Fix #371647, no response from maintainer since Oct 17.

(Portage version: 2.1.11.30/cvs/Linux x86_64, signed Manifest commit with key 4D7043C9)

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-cpp/gtest/gtest-1.6.0-r1.ebuild b/dev-cpp/gtest/gtest-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..9907f6617a64
--- /dev/null
+++ b/dev-cpp/gtest/gtest-1.6.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/gtest/gtest-1.6.0-r1.ebuild,v 1.1 2012/11/02 05:09:23 jsbronder Exp $
+
+EAPI="4"
+PYTHON_DEPEND="2"
+
+inherit eutils python autotools
+
+DESCRIPTION="Google C++ Testing Framework"
+HOMEPAGE="http://code.google.com/p/googletest/"
+SRC_URI="http://googletest.googlecode.com/files/${P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~ppc-macos"
+IUSE="examples threads static-libs"
+
+DEPEND="app-arch/unzip"
+RDEPEND=""
+
+pkg_setup() {
+	python_pkg_setup
+	python_set_active_version 2
+}
+
+src_prepare() {
+	sed -i -e "s|/tmp|${T}|g" test/gtest-filepath_test.cc || die
+	sed -i -r \
+		-e '/^install-(data|exec)-local:/s|^.*$|&\ndisabled-&|' \
+		Makefile.am || die
+	epatch "${FILESDIR}"/configure-fix-pthread-linking.patch || die
+	eautoreconf
+
+	python_convert_shebangs -r 2 .
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with threads pthreads)
+}
+
+src_test() {
+	# explicitly use parallel make
+	emake check || die
+}
+
+src_install() {
+	default
+	dobin scripts/gtest-config
+
+	if ! use static-libs ; then
+		rm "${ED}"/usr/lib*/*.la || die
+	fi
+
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins samples/*.{cc,h}
+	fi
+}