Version bump with DoS bugfix. Update HOMEPAGE & SRC_URI. https://github.com/gentoo/gentoo-portage-rsync-mirror/pull/98 by jbergstroem.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 92 insertions, 2 deletions

diff --git a/dev-db/pgbouncer/ChangeLog b/dev-db/pgbouncer/ChangeLog
index 29752656e66a..0c8abdc7af19 100644
--- a/dev-db/pgbouncer/ChangeLog
+++ b/dev-db/pgbouncer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/pgbouncer
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/pgbouncer/ChangeLog,v 1.14 2013/09/30 17:16:15 ago Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/pgbouncer/ChangeLog,v 1.15 2015/04/16 07:14:56 mgorny Exp $
+
+*pgbouncer-1.5.5 (16 Apr 2015)
+
+  16 Apr 2015; Michał Górny <mgorny@gentoo.org> +pgbouncer-1.5.5.ebuild:
+  Version bump with DoS bugfix. Update HOMEPAGE & SRC_URI.
+  https://github.com/gentoo/gentoo-portage-rsync-mirror/pull/98 by jbergstroem.
 
   30 Sep 2013; Agostino Sarubbo <ago@gentoo.org> pgbouncer-1.5.4-r1.ebuild:
   Stable for x86, wrt bug #485972
diff --git a/dev-db/pgbouncer/pgbouncer-1.5.5.ebuild b/dev-db/pgbouncer/pgbouncer-1.5.5.ebuild
new file mode 100644
index 000000000000..24214473d46c
--- /dev/null
+++ b/dev-db/pgbouncer/pgbouncer-1.5.5.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/pgbouncer/pgbouncer-1.5.5.ebuild,v 1.1 2015/04/16 07:14:56 mgorny Exp $
+
+EAPI="5"
+
+# Upstream has *way* broken tests.
+RESTRICT="test"
+
+inherit eutils user
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://pgbouncer.github.io"
+SRC_URI="https://pgbouncer.github.io/downloads/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc libevent udns"
+REQUIRED_USE="
+	libevent? ( !udns )
+	udns? ( !libevent )
+"
+RDEPEND="
+	>=sys-libs/glibc-2.10
+	libevent? ( >=dev-libs/libevent-2.0 )
+	udns? ( >=net-libs/udns-0.1 )
+"
+
+DEPEND="
+	${RDEPEND}
+	app-text/docbook-xml-dtd:4.5
+	app-text/xmlto
+	>=app-text/asciidoc-8.4
+"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash /var/lib/postgresql postgres
+
+	enewuser pgbouncer -1 -1 -1 postgres
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/pgbouncer-dirs.patch"
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_enable debug cassert) \
+		$(use_with libevent) \
+		$(use_with udns)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}