dev-libs/dee: Add correct handling of vala and introspection

(Portage version: 2.2.0_alpha171/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

2 files changed, 94 insertions, 1 deletions

diff --git a/dev-libs/dee/ChangeLog b/dev-libs/dee/ChangeLog
index 41e706ce944d..35430834ecc3 100644
--- a/dev-libs/dee/ChangeLog
+++ b/dev-libs/dee/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/dee
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dee/ChangeLog,v 1.15 2013/02/07 08:27:06 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dee/ChangeLog,v 1.16 2013/04/03 10:48:51 jlec Exp $
+
+*dee-1.0.14-r2 (03 Apr 2013)
+
+  03 Apr 2013; Justin Lecher <jlec@gentoo.org> +dee-1.0.14-r2.ebuild:
+  Add correct handling of vala and introspection
 
 *dee-1.0.14-r1 (07 Feb 2013)
 
diff --git a/dev-libs/dee/dee-1.0.14-r2.ebuild b/dev-libs/dee/dee-1.0.14-r2.ebuild
new file mode 100644
index 000000000000..685ee1740403
--- /dev/null
+++ b/dev-libs/dee/dee-1.0.14-r2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dee/dee-1.0.14-r2.ebuild,v 1.1 2013/04/03 10:48:51 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2,3_3} )
+
+AUTOTOOLS_AUTORECONF=y
+
+inherit autotools-utils vala python-r1
+
+DESCRIPTION="Provide objects allowing to create Model-View-Controller type programs across DBus"
+HOMEPAGE="https://launchpad.net/dee/"
+SRC_URI="https://launchpad.net/dee/1.0/${PV}/+download/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-3"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc debug examples +icu introspection static-libs test"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/icu:=
+	introspection? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	${vala_depend}
+	doc? ( dev-util/gtk-doc )
+	test? (
+		dev-libs/gtx
+		dev-util/dbus-test-runner
+		)"
+
+src_prepare() {
+	sed \
+		-e '/GCC_FLAGS/s:-g::' \
+		-e 's:vapigen:vapigen-0.14:g' \
+		-i configure.ac || die
+
+	sed \
+		-e 's:bindings::g' \
+		-i Makefile.am || die
+
+	vala_src_prepare
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-silent-rules
+		$(use_enable debug trace-log)
+		$(use_enable doc gtk-doc)
+		$(use_enable icu)
+		$(use_enable test tests)
+#		$(use_enable test extended-tests)
+		)
+	autotools-utils_src_configure
+	python_copy_sources
+}
+
+src_compile() {
+	autotools-utils_src_compile
+
+	compilation() {
+		cd "${BUILD_DIR}"/bindings || die
+		emake \
+			pyexecdir="$(python_get_sitedir)"
+	}
+	use introspection && python_foreach_impl compilation
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	installation() {
+		cd "${BUILD_DIR}"/bindings || die
+		emake \
+			PYGI_OVERRIDES_DIR="$(python_get_sitedir)"/gi/overrides \
+			DESTDIR="${D}" \
+			install
+	}
+	use introspection && python_foreach_impl installation
+
+	if use examples; then
+		insinto /usr/share/doc/${PN}/
+		doins -r examples
+	fi
+}