Build folks using >=vala-0.16 to prevent configure failure (bug #464500, thanks to Randy Barlow). Modernize ebuild. Remove gnome-3.4 era release.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 28 insertions, 102 deletions

diff --git a/dev-libs/folks/ChangeLog b/dev-libs/folks/ChangeLog
index 9b4ba691c862..e2415e43d739 100644
--- a/dev-libs/folks/ChangeLog
+++ b/dev-libs/folks/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/folks
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.28 2013/05/18 19:16:46 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.29 2013/06/07 03:14:17 tetromino Exp $
+
+  07 Jun 2013; Alexandre Rostovtsev <tetromino@gentoo.org> folks-0.4.3.ebuild,
+  -folks-0.6.9.ebuild:
+  Build folks using >=vala-0.16 to prevent configure failure (bug #464500,
+  thanks to Randy Barlow). Modernize ebuild. Remove gnome-3.4 era release.
 
   18 May 2013; Pacho Ramos <pacho@gentoo.org>
   +files/folks-0.9.1-automagic-fix1.patch,
diff --git a/dev-libs/folks/folks-0.4.3.ebuild b/dev-libs/folks/folks-0.4.3.ebuild
index f1ab09cb9cf0..f0e8611b1a96 100644
--- a/dev-libs/folks/folks-0.4.3.ebuild
+++ b/dev-libs/folks/folks-0.4.3.ebuild
@@ -1,11 +1,15 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.4.3.ebuild,v 1.8 2012/05/04 18:35:44 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.4.3.ebuild,v 1.9 2013/06/07 03:14:17 tetromino Exp $
 
-EAPI="3"
+EAPI="5"
 GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+GNOME_TARBALL_SUFFIX="bz2"
+VALA_MIN_API_VERSION="0.16" # see bug #464500
+VALA_USE_DEPEND="vapigen"
 
-inherit gnome2
+inherit gnome2 vala
 
 DESCRIPTION="libfolks is a library that aggregates people from multiple sources"
 HOMEPAGE="http://telepathy.freedesktop.org/wiki/Folks"
@@ -21,31 +25,28 @@ RDEPEND=">=dev-libs/glib-2.24:2
 	dev-libs/dbus-glib
 	<dev-libs/libgee-0.7:0
 	dev-libs/libxml2
-	sys-libs/ncurses
-	sys-libs/readline
+	sys-libs/ncurses:=
+	sys-libs/readline:=
 "
 DEPEND="${RDEPEND}
+	$(vala_depend)
 	>=dev-util/intltool-0.35.0
 	virtual/pkgconfig
-	>=dev-lang/vala-0.11.6:0.12[vapigen]
 	>=dev-libs/gobject-introspection-0.9.12
 	sys-devel/gettext
 "
 
-pkg_setup() {
-	DOCS="AUTHORS ChangeLog NEWS README"
-	G2CONF="${G2CONF}
-		--enable-import-tool
-		--enable-inspect-tool
-		--enable-vala
-		VALAC=$(type -p valac-0.12)
-		VAPIGEN=$(type -p vapigen-0.12)
-		--disable-docs
-		--disable-Werror"
-	# Rebuilding docs needs valadoc, which has no release
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
 }
 
-src_install() {
-	gnome2_src_install
-	find "${ED}" -name "*.la" -delete || die "la files removal failed"
+src_configure() {
+	gnome2_src_configure \
+		--enable-import-tool \
+		--enable-inspect-tool \
+		--enable-vala \
+		--disable-docs \
+		--disable-Werror
+	# Rebuilding docs needs valadoc, which has no release
 }
diff --git a/dev-libs/folks/folks-0.6.9.ebuild b/dev-libs/folks/folks-0.6.9.ebuild
deleted file mode 100644
index 53030ce30304..000000000000
--- a/dev-libs/folks/folks-0.6.9.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.6.9.ebuild,v 1.1 2012/05/07 07:45:01 tetromino Exp $
-
-EAPI="4"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-
-inherit gnome2
-
-DESCRIPTION="libfolks is a library that aggregates people from multiple sources"
-HOMEPAGE="http://telepathy.freedesktop.org/wiki/Folks"
-
-LICENSE="LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-linux"
-IUSE="eds socialweb test tracker utils vala"
-
-COMMON_DEPEND=">=dev-libs/glib-2.24:2
-	>=net-libs/telepathy-glib-0.17.5
-	dev-libs/dbus-glib
-	<dev-libs/libgee-0.7:0[introspection]
-	dev-libs/libxml2
-	>=gnome-base/gconf-2.31
-	sys-libs/ncurses
-	sys-libs/readline
-
-	eds? ( >=gnome-extra/evolution-data-server-3.1.5 )
-	socialweb? ( >=net-libs/libsocialweb-0.25.20 )
-	tracker? ( >=app-misc/tracker-0.14 )"
-
-# telepathy-mission-control needed at runtime; it is used by the telepathy
-# backend via telepathy-glib's AccountManager binding.
-RDEPEND="${COMMON_DEPEND}
-	net-im/telepathy-mission-control"
-
-# folks socialweb backend requires that libsocialweb be built with USE=vala,
-# even when building folks with --disable-vala.
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/gobject-introspection-1.30
-	>=dev-util/intltool-0.35.0
-	sys-devel/gettext
-	virtual/pkgconfig
-
-	socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
-	test? ( sys-apps/dbus )
-	vala? (
-		>=dev-lang/vala-0.15.2:0.16[vapigen]
-		>=net-libs/telepathy-glib-0.13.1[vala]
-		eds? ( >=gnome-extra/evolution-data-server-3.0.1[vala] ) )"
-
-# the inspect tool requires --enable-vala
-REQUIRED_USE="utils? ( vala )"
-
-pkg_setup() {
-	DOCS="AUTHORS ChangeLog NEWS README"
-	# Rebuilding docs needs valadoc, which has no release
-	G2CONF="${G2CONF}
-		$(use_enable eds eds-backend)
-		$(use_enable socialweb libsocialweb-backend)
-		$(use_enable tracker tracker-backend)
-		$(use_enable utils inspect-tool)
-		$(use_enable vala)
-		--enable-import-tool
-		--disable-docs
-		--disable-fatal-warnings
-		--disable-Werror"
-	if use vala; then
-		G2CONF="${G2CONF}
-			VALAC=$(type -p valac-0.16)
-			VAPIGEN=$(type -p vapigen-0.16)"
-	fi
-}
-
-src_test() {
-	# FIXME: eds tests often fails for no good reason
-	sed -e 's/check: .*/check: /' \
-		-i tests/eds/Makefile || die "sed failed"
-	default
-}