Drop USE=debug as it only controls -g flags. Add USE=static-libs support. Fix AR/CPPFLAGS handling.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 57 insertions, 1 deletions

diff --git a/dev-libs/hiredis/ChangeLog b/dev-libs/hiredis/ChangeLog
index 9b9e2726b5b9..a42f4cd9e341 100644
--- a/dev-libs/hiredis/ChangeLog
+++ b/dev-libs/hiredis/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/hiredis
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/hiredis/ChangeLog,v 1.9 2014/06/16 02:25:52 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/hiredis/ChangeLog,v 1.10 2014/06/16 02:35:46 vapier Exp $
+
+*hiredis-0.11.0-r1 (16 Jun 2014)
+
+  16 Jun 2014; Mike Frysinger <vapier@gentoo.org> +hiredis-0.11.0-r1.ebuild:
+  Drop USE=debug as it only controls -g flags.  Add USE=static-libs support.
+  Fix AR/CPPFLAGS handling.
 
   16 Jun 2014; Mike Frysinger <vapier@gentoo.org> hiredis-0.11.0.ebuild:
   Add arm love #511026.
diff --git a/dev-libs/hiredis/hiredis-0.11.0-r1.ebuild b/dev-libs/hiredis/hiredis-0.11.0-r1.ebuild
new file mode 100644
index 000000000000..22053d3a8cfc
--- /dev/null
+++ b/dev-libs/hiredis/hiredis-0.11.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/hiredis/hiredis-0.11.0-r1.ebuild,v 1.1 2014/06/16 02:35:45 vapier Exp $
+
+EAPI=4
+
+inherit eutils multilib
+
+DESCRIPTION="Minimalistic C client library for the Redis database"
+HOMEPAGE="http://github.com/redis/hiredis"
+SRC_URI="http://github.com/redis/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~x86 ~x86-fbsd ~x64-solaris"
+IUSE="static-libs"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-disable-network-tests.patch"
+
+	# use GNU ld syntax on Solaris
+	sed -i -e '/DYLIB_MAKE_CMD=.* -G/d' Makefile || die
+}
+
+_emake() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		ARCH= \
+		DEBUG= \
+		OPTIMIZATION="${CPPFLAGS}" \
+		"$@"
+}
+
+src_compile() {
+	# The static lib re-uses the same objects as the shared lib, so
+	# overhead is low w/creating it all the time.  It's also needed
+	# by the tests.
+	_emake dynamic static
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake PREFIX="${ED}/usr" LIBRARY_PATH="$(get_libdir)" install
+	use static-libs || rm "${ED}/usr/$(get_libdir)/libhiredis.a"
+	dodoc CHANGELOG.md README.md
+}