Provide GTK+-3.0 version in SLOT="3"

(Portage version: 2.2.0_alpha77/cvs/Linux x86_64)

4 files changed, 150 insertions, 1 deletions

diff --git a/dev-libs/libappindicator/ChangeLog b/dev-libs/libappindicator/ChangeLog
index 95e47b1cc783..a4b96213b78c 100644
--- a/dev-libs/libappindicator/ChangeLog
+++ b/dev-libs/libappindicator/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/libappindicator
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libappindicator/ChangeLog,v 1.3 2011/11/20 12:16:38 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libappindicator/ChangeLog,v 1.4 2011/11/28 15:04:24 ssuominen Exp $
+
+*libappindicator-0.4.1-r300 (28 Nov 2011)
+*libappindicator-0.4.1-r201 (28 Nov 2011)
+
+  28 Nov 2011; Samuli Suominen <ssuominen@gentoo.org>
+  +libappindicator-0.4.1-r201.ebuild, +libappindicator-0.4.1-r300.ebuild,
+  +files/libappindicator-0.4.1-gtk.patch:
+  Provide GTK+-3.0 version in SLOT="3"
 
   20 Nov 2011; Samuli Suominen <ssuominen@gentoo.org> metadata.xml:
   Move to ayatana herd.
diff --git a/dev-libs/libappindicator/files/libappindicator-0.4.1-gtk.patch b/dev-libs/libappindicator/files/libappindicator-0.4.1-gtk.patch
new file mode 100644
index 000000000000..e36391103f08
--- /dev/null
+++ b/dev-libs/libappindicator/files/libappindicator-0.4.1-gtk.patch
@@ -0,0 +1,16 @@
+--- src/app-indicator.c
++++ src/app-indicator.c
+@@ -33,8 +33,13 @@
+ 
+ #include <libdbusmenu-glib/menuitem.h>
+ #include <libdbusmenu-glib/server.h>
++#ifdef HAVE_GTK3
++#include <libdbusmenu-gtk3/client.h>
++#include <libdbusmenu-gtk3/parser.h>
++#else
+ #include <libdbusmenu-gtk/client.h>
+ #include <libdbusmenu-gtk/parser.h>
++#endif
+ 
+ #include <libindicator/indicator-desktop-shortcuts.h>
+ 
diff --git a/dev-libs/libappindicator/libappindicator-0.4.1-r201.ebuild b/dev-libs/libappindicator/libappindicator-0.4.1-r201.ebuild
new file mode 100644
index 000000000000..95062a52978b
--- /dev/null
+++ b/dev-libs/libappindicator/libappindicator-0.4.1-r201.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libappindicator/libappindicator-0.4.1-r201.ebuild,v 1.1 2011/11/28 15:04:24 ssuominen Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.7"
+
+inherit autotools eutils python
+
+__vala_version=0.14
+
+DESCRIPTION="A library to allow applications to export a menu into the Unity Menu bar"
+HOMEPAGE="http://launchpad.net/libappindicator"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+# FIXME: Missing dev-lang/mono handling!
+RDEPEND="dev-libs/dbus-glib
+	>=dev-libs/glib-2.26
+	dev-libs/libdbusmenu[gtk,-gtk3]
+	>=dev-libs/libindicator-0.4
+	dev-python/pygobject:2
+	>=dev-python/pygtk-2.14:2
+	>=x11-libs/gtk+-2.18:2
+	introspection? ( >=dev-libs/gobject-introspection-0.10 )"
+DEPEND="${RDEPEND}
+	dev-lang/vala:${__vala_version}[vapigen]
+	dev-util/gtk-doc-am
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e '/LDFLAGS/s:python2.6:python2.7:' bindings/python/Makefile.{am,in} || die
+	epatch "${FILESDIR}"/${P}-no-mono.patch
+	eautoreconf
+
+	rm -f py-compile
+	ln -s $(type -P true) py-compile
+}
+
+src_configure() {
+	export VALAC="$(type -P valac-${__vala_version})"
+
+	econf \
+		--disable-static \
+		--with-gtk=2
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	find "${ED}"usr -name '*.la' -exec rm -f {} +
+
+	# SLOT="3" has eveything required
+	rm -rf "${ED}"usr/share/gtk-doc
+}
+
+pkg_postinst() {
+	python_mod_optimize appindicator
+}
+
+pkg_postrm() {
+	python_mod_cleanup appindicator
+}
diff --git a/dev-libs/libappindicator/libappindicator-0.4.1-r300.ebuild b/dev-libs/libappindicator/libappindicator-0.4.1-r300.ebuild
new file mode 100644
index 000000000000..042765e6b355
--- /dev/null
+++ b/dev-libs/libappindicator/libappindicator-0.4.1-r300.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libappindicator/libappindicator-0.4.1-r300.ebuild,v 1.1 2011/11/28 15:04:24 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils
+
+PN_vala_version=0.14
+
+DESCRIPTION="A library to allow applications to export a menu into the Unity Menu bar"
+HOMEPAGE="http://launchpad.net/libappindicator"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+# FIXME: Missing dev-lang/mono handling!
+RDEPEND="dev-libs/dbus-glib
+	>=dev-libs/glib-2.26
+	dev-libs/libdbusmenu[gtk,gtk3]
+	>=dev-libs/libindicator-0.4:3
+	x11-libs/gtk+:3
+	introspection? ( >=dev-libs/gobject-introspection-0.10 )"
+DEPEND="${RDEPEND}
+	dev-lang/vala:${PN_vala_version}[vapigen]
+	dev-util/gtk-doc-am
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-no-mono.patch \
+		"${FILESDIR}"/${P}-gtk.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	export VALAC="$(type -P valac-${PN_vala_version})"
+
+	econf \
+		--disable-static \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		--with-gtk=3
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog
+
+	find "${ED}"usr -name '*.la' -exec rm -f {} +
+}