Finally the libcdio version bump. This also fixes building of examples that was unneeded. Rename nocxx USE flag in cxx and enable it by default through EAPI=1.

(Portage version: 2.1.5.5)

2 files changed, 77 insertions, 1 deletions

diff --git a/dev-libs/libcdio/ChangeLog b/dev-libs/libcdio/ChangeLog
index 3f400806bddc..266fde2ac1ea 100644
--- a/dev-libs/libcdio/ChangeLog
+++ b/dev-libs/libcdio/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/libcdio
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/ChangeLog,v 1.93 2008/04/20 22:35:37 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/ChangeLog,v 1.94 2008/06/13 13:46:30 flameeyes Exp $
+
+*libcdio-0.80 (13 Jun 2008)
+
+  13 Jun 2008; Diego Pettenò <flameeyes@gentoo.org> +libcdio-0.80.ebuild:
+  Finally the libcdio version bump. This also fixes building of examples
+  that was unneeded. Rename nocxx USE flag in cxx and enable it by default
+  through EAPI=1.
 
   20 Apr 2008; Ryan Hill <dirtyepic@gentoo.org>
   +files/libcdio-0.79-gcc-4.3-include.patch, libcdio-0.79-r1.ebuild:
diff --git a/dev-libs/libcdio/libcdio-0.80.ebuild b/dev-libs/libcdio/libcdio-0.80.ebuild
new file mode 100644
index 000000000000..6e4b5b81e8eb
--- /dev/null
+++ b/dev-libs/libcdio/libcdio-0.80.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/libcdio-0.80.ebuild,v 1.1 2008/06/13 13:46:30 flameeyes Exp $
+
+EAPI=1
+
+inherit eutils libtool multilib
+
+DESCRIPTION="A library to encapsulate CD-ROM reading and control"
+HOMEPAGE="http://www.gnu.org/software/libcdio/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="cddb minimal nls +cxx"
+
+RDEPEND="cddb? ( >=media-libs/libcddb-1.0.1 )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	dev-util/pkgconfig"
+
+RESTRICT="test"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-0.79-gcc-4.3-include.patch
+	elibtoolize
+}
+
+src_compile() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable cddb) \
+		$(use_with !minimal cd-drive) \
+		$(use_with !minimal cd-info) \
+		$(use_with !minimal cd-paranoia) \
+		$(use_with !minimal cdda-player) \
+		$(use_with !minimal cd-read) \
+		$(use_with !minimal iso-info) \
+		$(use_with !minimal iso-read) \
+		$(use_enable cxx) \
+		--disable-example-progs --disable-cpp-progs \
+		--with-cd-paranoia-name=libcdio-paranoia \
+		--disable-vcd-info \
+		--disable-dependency-tracking \
+		--disable-maintainer-mode || die "configure failed"
+	emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README THANKS
+
+	# maybe next version is fixed
+	if use minimal; then
+		rm -f "${D}/usr/$(get_libdir)/pkgconfig/libcdio_cdda.pc"
+		rm -f "${D}/usr/include/cdio/cdda.h"
+	fi
+}
+
+pkg_postinst() {
+	ewarn "If you've upgraded from a previous version of ${PN}, you may need to re-emerge"
+	ewarn "packages that linked against ${PN} (vlc, vcdimager and more) by running:"
+	ewarn "\trevdep-rebuild"
+}