Version bump.

Signed-off-by: Andrew Savchenko <bircoph@gentoo.org>
(Portage version: 2.2.20/cvs/Linux i686, signed Manifest commit with key 565953B95372756C)

3 files changed, 86 insertions, 1 deletions

diff --git a/dev-libs/libclsync/ChangeLog b/dev-libs/libclsync/ChangeLog
index 00f353799a3f..e22485e4c4c3 100644
--- a/dev-libs/libclsync/ChangeLog
+++ b/dev-libs/libclsync/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libclsync
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libclsync/ChangeLog,v 1.1 2015/02/11 03:35:23 bircoph Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libclsync/ChangeLog,v 1.2 2015/05/25 00:12:42 bircoph Exp $
+
+*libclsync-0.4.1 (25 May 2015)
+
+  25 May 2015; Andrew Savchenko <bircoph@gentoo.org> +libclsync-0.4.1.ebuild:
+  Version bump. Add extra debugging support.
 
 *libclsync-0.4 (11 Feb 2015)
 
diff --git a/dev-libs/libclsync/libclsync-0.4.1.ebuild b/dev-libs/libclsync/libclsync-0.4.1.ebuild
new file mode 100644
index 000000000000..2db78f0e7fc0
--- /dev/null
+++ b/dev-libs/libclsync/libclsync-0.4.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libclsync/libclsync-0.4.1.ebuild,v 1.1 2015/05/25 00:12:42 bircoph Exp $
+
+EAPI=5
+
+MY_PN=${PN#lib}
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/xaionaro/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/xaionaro/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+inherit autotools eutils
+
+DESCRIPTION="Control and monitoring library for clsync"
+HOMEPAGE="http://ut.mephi.ru/oss/clsync https://github.com/xaionaro/clsync"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="debug extra-debug extra-hardened hardened static-libs"
+REQUIRED_USE="
+	extra-debug? ( debug )
+	extra-hardened? ( hardened )
+"
+
+DEPEND="virtual/pkgconfig "
+RDEPEND="=app-doc/clsync-docs-0.4*"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	local harden_level=0
+	use hardened && harden_level=1
+	use extra-hardened && harden_level=2
+
+	local debug_level=0
+	use debug && debug_level=1
+	use extra-debug && debug_level=2
+
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--enable-socket-library \
+		--disable-clsync \
+		--enable-debug=${debug_level} \
+		--enable-paranoid=${harden_level} \
+		--without-bsm \
+		--without-kqueue \
+		--disable-capabilities \
+		--disable-cluster \
+		--enable-socket \
+		--disable-highload-locks \
+		--disable-unshare \
+		--disable-seccomp \
+		--without-libcgroup \
+		--without-gio \
+		--with-inotify=native \
+		--without-mhash
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files
+	use static-libs || find "${ED}" -name "*.a" -delete || die "failed to remove static libs"
+
+	# docs go into clsync-docs
+	rm -rf "${ED}/usr/share/doc" || die
+}
+
+pkg_postinst() {
+	einfo "clsync instances you are going to use _must_ be compiled"
+	einfo "with control-socket support"
+}
diff --git a/dev-libs/libclsync/metadata.xml b/dev-libs/libclsync/metadata.xml
index e0215a9b72c3..f4f447830981 100644
--- a/dev-libs/libclsync/metadata.xml
+++ b/dev-libs/libclsync/metadata.xml
@@ -10,6 +10,7 @@
   <pkg>app-admin/clsync</pkg> processes.
 </longdescription>
 <use>
+	<flag name="extra-debug">Enable extra debugging. This will hurt performance badly. Be ready for tons of output.</flag>
 	<flag name="extra-hardened">Enable extra security checks. This may hurt performance.</flag>
 </use>
 </pkgmetadata>