Convert to multilib and stack it for medialibs r10

(Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 61 insertions, 2 deletions

diff --git a/dev-libs/liboil/ChangeLog b/dev-libs/liboil/ChangeLog
index 57d150258bed..e433c0205f4f 100644
--- a/dev-libs/liboil/ChangeLog
+++ b/dev-libs/liboil/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/liboil
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/liboil/ChangeLog,v 1.92 2012/10/29 00:56:43 tetromino Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liboil/ChangeLog,v 1.93 2013/08/10 20:36:54 aballier Exp $
+
+*liboil-0.3.17-r2 (10 Aug 2013)
+
+  10 Aug 2013; Alexis Ballier <aballier@gentoo.org> +liboil-0.3.17-r2.ebuild:
+  Convert to multilib and stack it for medialibs r10
 
 *liboil-0.3.17-r1 (29 Oct 2012)
 
diff --git a/dev-libs/liboil/liboil-0.3.17-r2.ebuild b/dev-libs/liboil/liboil-0.3.17-r2.ebuild
new file mode 100644
index 000000000000..7486d9f7393b
--- /dev/null
+++ b/dev-libs/liboil/liboil-0.3.17-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liboil/liboil-0.3.17-r2.ebuild,v 1.1 2013/08/10 20:36:54 aballier Exp $
+
+EAPI=5
+inherit eutils flag-o-matic multilib autotools-multilib
+
+DESCRIPTION="Library of simple functions that are optimized for various CPUs"
+HOMEPAGE="http://liboil.freedesktop.org/"
+SRC_URI="http://liboil.freedesktop.org/download/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0.3"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+examples static-libs test"
+
+RDEPEND="examples? ( dev-libs/glib:2 )
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r9
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig"
+DOCS=( AUTHORS BUG-REPORTING HACKING NEWS README )
+
+src_prepare() {
+	if ! use examples; then
+		sed "s/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/" \
+			-i Makefile.am Makefile.in || die
+	fi
+
+	if ! use test; then
+		sed "s/^\(SUBDIRS =.*\)testsuite\(.*\)$/\1\2/" \
+			-i Makefile.am Makefile.in || die
+	fi
+
+	epatch "${FILESDIR}/${P}-amd64-cpuid.patch"
+	has x32 $(get_all_abis) && epatch "${FILESDIR}"/${PN}-0.3.17-x32.patch
+}
+
+src_configure() {
+	strip-flags
+	filter-flags -O?
+	append-flags -O2
+
+	autotools-multilib_src_configure
+}
+
+pkg_postinst() {
+	if ! use examples; then
+		ewarn "You have disabled examples USE flag. Beware that upstream might"
+		ewarn "want the output of some utilities that are only built with"
+		ewarn "USE='examples' if you report bugs to them."
+	fi
+}