Version bump.

(Portage version: 15411-svn/cvs/Linux x86_64)

2 files changed, 76 insertions, 1 deletions

diff --git a/dev-libs/openct/ChangeLog b/dev-libs/openct/ChangeLog
index b8de2a3e0f09..d5c23f22f2b7 100644
--- a/dev-libs/openct/ChangeLog
+++ b/dev-libs/openct/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/openct
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.83 2010/02/12 19:04:33 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.84 2010/02/20 20:26:02 arfrever Exp $
+
+*openct-0.6.20 (20 Feb 2010)
+
+  20 Feb 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +openct-0.6.20.ebuild:
+  Version bump.
 
   12 Feb 2010; Joseph Jezak <josejx@gentoo.org> openct-0.6.19.ebuild:
   Marked ppc/ppc64 stable for bug #304001.
diff --git a/dev-libs/openct/openct-0.6.20.ebuild b/dev-libs/openct/openct-0.6.20.ebuild
new file mode 100644
index 000000000000..b7c167ab6856
--- /dev/null
+++ b/dev-libs/openct/openct-0.6.20.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.20.ebuild,v 1.1 2010/02/20 20:26:02 arfrever Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="library for accessing smart card terminals"
+HOMEPAGE="http://www.opensc-project.org/openct/"
+
+SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc pcsc-lite usb"
+
+RDEPEND="pcsc-lite? ( sys-apps/pcsc-lite )
+		usb? ( virtual/libusb:0 )
+		>=sys-fs/udev-096"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+pkg_setup() {
+	enewgroup openct
+	enewuser openctd
+}
+
+src_configure() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--htmldir="/usr/share/doc/${PF}/html" \
+		--localstatedir=/var \
+		--with-udev="/$(get_libdir)/udev" \
+		--enable-non-privileged \
+		--with-daemon-user=openctd \
+		--with-daemon-groups=usb \
+		$(use_enable doc) \
+		$(use_enable doc api-doc) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_enable usb)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	insinto /etc/udev/rules.d/
+	newins etc/openct.udev 70-openct.rules || die "newins 70-openct.rules failed"
+
+	diropts -m0750 -gopenct -oopenctd
+	keepdir /var/run/openct
+
+	newinitd "${FILESDIR}"/openct.rc openct
+}
+
+pkg_postinst() {
+	elog
+	elog "You need to edit /etc/openct.conf to enable serial readers."
+	elog
+	elog "You should add \"openct\" to your default runlevel. To do so"
+	elog "type \"rc-update add openct default\"."
+	elog
+	elog "You need to be a member of the (newly created) group openct to"
+	elog "access smart card readers connected to this system. Set users'"
+	elog "groups with usermod -G.  root always has access."
+	elog
+}