Bump for #368943

(Portage version: 2.2.0_alpha47/cvs/Linux x86_64)

2 files changed, 86 insertions, 1 deletions

diff --git a/dev-python/dbus-python/ChangeLog b/dev-python/dbus-python/ChangeLog
index 35abd3aa506f..8fc6b66504c8 100644
--- a/dev-python/dbus-python/ChangeLog
+++ b/dev-python/dbus-python/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/dbus-python
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/ChangeLog,v 1.69 2011/03/20 17:30:04 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/ChangeLog,v 1.70 2011/07/28 23:08:11 patrick Exp $
+
+*dbus-python-0.84.0 (28 Jul 2011)
+
+  28 Jul 2011; Patrick Lauer <patrick@gentoo.org> +dbus-python-0.84.0.ebuild:
+  Bump for #368943
 
   20 Mar 2011; Samuli Suominen <ssuominen@gentoo.org>
   dbus-python-0.83.2.ebuild:
diff --git a/dev-python/dbus-python/dbus-python-0.84.0.ebuild b/dev-python/dbus-python/dbus-python-0.84.0.ebuild
new file mode 100644
index 000000000000..45abf111e1d9
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-0.84.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/dbus-python-0.84.0.ebuild,v 1.1 2011/07/28 23:08:11 patrick Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+PYTHON_EXPORT_PHASE_FUNCTIONS="1"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+
+inherit eutils multilib python
+
+DESCRIPTION="Python bindings for the D-Bus messagebus."
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/DBusBindings \
+http://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.88
+	>=sys-apps/dbus-1.4.1"
+DEPEND="${RDEPEND}
+	doc? ( =dev-python/epydoc-3* )
+	test? ( dev-python/pygobject )
+	dev-util/pkgconfig"
+
+src_prepare() {
+	# Disable compiling of .pyc files.
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+
+	# Workaround testsuite issues
+	epatch "${FILESDIR}/${PN}-0.83.1-workaround-broken-test.patch"
+
+	python_src_prepare
+}
+
+src_configure() {
+	configuration() {
+		econf \
+			--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+			$(use_enable doc api-docs)
+	}
+	python_execute_function -s configuration
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_src_test
+}
+
+src_install() {
+	python_src_install
+
+	if use doc; then
+		install_documentation() {
+			dohtml api/* || return 1
+		}
+		python_execute_function -f -q -s install_documentation
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/
+		doins -r examples || die
+	fi
+
+	python_clean_installation_image
+}
+
+pkg_postinst() {
+	python_mod_optimize dbus dbus_bindings.py
+}
+
+pkg_postrm() {
+	python_mod_cleanup dbus dbus_bindings.py
+}