bump; add py3.3 support, add IUSE test, tidy deps, add REQUIRED_USE settings to cater to USE flags supporting only py2 capable deps

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 64 insertions, 2 deletions

diff --git a/dev-python/django-extensions/ChangeLog b/dev-python/django-extensions/ChangeLog
index 34e60018006b..5b293bf119ab 100644
--- a/dev-python/django-extensions/ChangeLog
+++ b/dev-python/django-extensions/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/django-extensions
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/ChangeLog,v 1.6 2013/05/22 07:48:57 idella4 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/ChangeLog,v 1.7 2014/03/26 03:38:36 idella4 Exp $
+
+*django-extensions-1.3.3 (26 Mar 2014)
+
+  26 Mar 2014; Ian Delaney <idella4@gentoo.org> +django-extensions-1.3.3.ebuild:
+  bump; add py3.3 support, add IUSE test, tidy deps, add REQUIRED_USE settings
+  to cater to USE flags supporting only py2 capable deps
 
 *django-extensions-1.0.2-r1 (22 May 2013)
 
diff --git a/dev-python/django-extensions/django-extensions-1.3.3.ebuild b/dev-python/django-extensions/django-extensions-1.3.3.ebuild
new file mode 100644
index 000000000000..0dc817a05764
--- /dev/null
+++ b/dev-python/django-extensions/django-extensions-1.3.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/django-extensions-1.3.3.ebuild,v 1.1 2014/03/26 03:38:36 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_3} )
+
+inherit distutils-r1
+
+GIT_HASH_TAG="47a531c"
+
+DESCRIPTION="Django Command Extensions"
+HOMEPAGE="http://github.com/django-extensions/django-extensions http://code.google.com/p/django-command-extensions/"
+SRC_URI="http://github.com/django-extensions/django-extensions/tarball/${PV}/${P}.tgz"
+
+LICENSE="BSD || ( MIT GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc graphviz mysql postgres s3 sqlite test vcard"
+# Req'd for tests
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PY2_USEDEP=$(python_gen_usedep 'python2*')
+RDEPEND=">=dev-python/django-1.5.4[${PYTHON_USEDEP},mysql?,postgres?,sqlite?]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	graphviz? ( dev-python/pygraphviz[${PY2_USEDEP}] )
+	s3? ( dev-python/boto[${PY2_USEDEP}] )
+	vcard? ( dev-python/vobject[${PY2_USEDEP}] )"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND} )"
+
+S="${WORKDIR}/${PN}-${PN}-${GIT_HASH_TAG}"
+
+PY2_REQUSE="|| ( $(python_gen_useflags python2* ) )"
+REQUIRED_USE="
+	graphviz? ( ${PY2_REQUSE} )
+	s3? ( ${PY2_REQUSE} )
+	vcard? ( ${PY2_REQUSE} )"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" run_tests.py || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}