Version bump. Possible API break.

(Portage version: 2.1.10.10/cvs/Linux x86_64)

2 files changed, 79 insertions, 1 deletions

diff --git a/dev-python/enable/ChangeLog b/dev-python/enable/ChangeLog
index bced5e53159f..ec3059695e1b 100644
--- a/dev-python/enable/ChangeLog
+++ b/dev-python/enable/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/enable
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/enable/ChangeLog,v 1.11 2011/03/27 22:30:16 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/enable/ChangeLog,v 1.12 2011/08/03 23:52:32 bicatali Exp $
+
+*enable-4.0.0 (03 Aug 2011)
+
+  03 Aug 2011; Sébastien Fabbro <bicatali@gentoo.org> +enable-4.0.0.ebuild:
+  Version bump. Possible API break.
 
 *enable-3.4.1 (27 Mar 2011)
 
diff --git a/dev-python/enable/enable-4.0.0.ebuild b/dev-python/enable/enable-4.0.0.ebuild
new file mode 100644
index 000000000000..110edfebdb9b
--- /dev/null
+++ b/dev-python/enable/enable-4.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/enable/enable-4.0.0.ebuild,v 1.1 2011/08/03 23:52:32 bicatali Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils eutils virtualx
+
+DESCRIPTION="Enthought Tool Suite: drawing and interaction packages"
+HOMEPAGE="http://code.enthought.com/projects/enable/ http://pypi.python.org/pypi/enable"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/numpy
+	dev-python/reportlab
+	>=dev-python/traitsui-4.0
+	>=media-libs/freetype-2
+	virtual/opengl
+	x11-libs/libX11"
+DEPEND="dev-python/setuptools
+	dev-lang/swig
+	dev-python/cython
+	doc? ( dev-python/sphinx )
+	test? (
+		${RDEPEND}
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)"
+
+DOCS="docs/*.txt"
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	testing() {
+		PYTHONPATH="$(ls -d ${S}/build-${PYTHON_ABI}/lib*)" distutils_src_test
+	}
+	VIRTUALX_COMMAND="testing" virtualmake
+}
+
+src_install() {
+	find -name "*LICENSE*.txt" -delete
+	distutils_src_install
+
+	if use doc; then
+		pushd docs/build/html > /dev/null
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/* || die "Installation of examples failed"
+	fi
+}