revbump to support python 3.3 and removing beaker from deps. fixes 488950

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key F97A36A1)

2 files changed, 76 insertions, 1 deletions

diff --git a/dev-python/mako/ChangeLog b/dev-python/mako/ChangeLog
index 43eaaa866151..e56b4a3e8388 100644
--- a/dev-python/mako/ChangeLog
+++ b/dev-python/mako/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/mako
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/mako/ChangeLog,v 1.72 2013/10/22 02:32:38 yac Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mako/ChangeLog,v 1.73 2013/10/22 02:40:35 yac Exp $
+
+*mako-0.7.3-r2 (22 Oct 2013)
+
+  22 Oct 2013; Jan Matejka <yac@gentoo.org> +mako-0.7.3-r2.ebuild:
+  revbump to support python 3.3 and removing beaker from deps. fixes 488950
 
   22 Oct 2013; Jan Matejka <yac@gentoo.org> -mako-0.7.3-r2.ebuild:
   reverting last commit before it gets published
diff --git a/dev-python/mako/mako-0.7.3-r2.ebuild b/dev-python/mako/mako-0.7.3-r2.ebuild
new file mode 100644
index 000000000000..2857ac579553
--- /dev/null
+++ b/dev-python/mako/mako-0.7.3-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1998-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mako/mako-0.7.3-r2.ebuild,v 1.3 2013/10/22 02:40:35 yac Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit readme.gentoo versionator distutils-r1
+
+MY_P="Mako-${PV}"
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ http://pypi.python.org/pypi/Mako"
+SRC_URI="http://www.makotemplates.org/downloads/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/test-fix.patch"
+)
+
+DOC_CONTENTS="
+${PN} can be enchanced with caching by dev-python/beaker"
+
+python_test() {
+	cp -r -l test "${BUILD_DIR}"/ || die
+
+	if [[ ${EPYTHON} == python3.* ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w "${BUILD_DIR}"/test || die
+	fi
+
+	cd "${BUILD_DIR}"/test || die
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -rf doc/build
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	for v in ${REPLACING_VERSIONS}; do
+		if ! version_is_at_least 0.7.3-r2 $v; then
+			ewarn "dev-python/beaker is no longer hard dependency of ${P}"
+			ewarn "If you rely on it, you should add beaker to your"
+			ewarn "/var/lib/portage/world file"
+			break
+		fi
+	done
+}