Migrate to distutils-r1.

(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 9627F456F9DA7643!)

2 files changed, 63 insertions, 2 deletions

diff --git a/dev-python/beaker/ChangeLog b/dev-python/beaker/ChangeLog
index 384cc54300ff..9b2787bf2f50 100644
--- a/dev-python/beaker/ChangeLog
+++ b/dev-python/beaker/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/beaker
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/beaker/ChangeLog,v 1.47 2012/11/16 13:35:27 blueness Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/beaker/ChangeLog,v 1.48 2013/02/22 00:03:12 mgorny Exp $
+
+*beaker-1.6.4-r1 (22 Feb 2013)
+
+  22 Feb 2013; Michał Górny <mgorny@gentoo.org> +beaker-1.6.4-r1.ebuild:
+  Migrate to distutils-r1.
 
   16 Nov 2012; Anthony G. Basile <blueness@gentoo.org> beaker-1.6.4.ebuild:
   keyword ~ppc64, bug #411761
diff --git a/dev-python/beaker/beaker-1.6.4-r1.ebuild b/dev-python/beaker/beaker-1.6.4-r1.ebuild
new file mode 100644
index 000000000000..54d7617baa70
--- /dev/null
+++ b/dev-python/beaker/beaker-1.6.4-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/beaker/beaker-1.6.4-r1.ebuild,v 1.1 2013/02/22 00:03:12 mgorny Exp $
+
+EAPI=5
+
+# py2.5 seems to have db problems
+# pypy random exceptions, someone should take a closer look, it may
+# be just the usual test suite overload
+# py3.3 unfit with some types
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2} )
+
+inherit distutils-r1
+
+MY_PN="Beaker"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A Session and Caching library with WSGI Middleware"
+HOMEPAGE="http://beaker.groovie.org/ http://pypi.python.org/pypi/Beaker"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="test"
+
+# webtest-based tests are skipped when webtest is not installed
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/webtest[$(python_gen_usedep python{2_6,2_7,3_2,3_3})] )"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Workaround for http://bugs.python.org/issue11276.
+	sed -e "s/import anydbm/& as anydbm/;/import anydbm/a dbm = anydbm" \
+		-i beaker/container.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/ || die
+
+	if [[ ${EPYTHON} == python3.* ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w "${BUILD_DIR}"/tests || die
+	fi
+
+	cd "${BUILD_DIR}"/tests || die
+	nosetests || die "Tests fail with ${EPYTHON}"
+}