Version bump for missing pkg-config dependency. Drop alpha,ia64,sparc keywords accordingly, bug 391759.

(Portage version: 2.1.10.11/cvs/Linux x86_64)

2 files changed, 80 insertions, 1 deletions

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index 5744bee9c55f..f2d67620279e 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.66 2011/10/30 10:39:00 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.67 2011/11/24 07:11:01 graaff Exp $
+
+*rcairo-1.10.2 (24 Nov 2011)
+
+  24 Nov 2011; Hans de Graaff <graaff@gentoo.org> +rcairo-1.10.2.ebuild:
+  Version bump for missing pkg-config dependency. Drop alpha,ia64,sparc
+  keywords accordingly, bug 391759.
 
 *rcairo-1.10.1 (30 Oct 2011)
 
diff --git a/dev-ruby/rcairo/rcairo-1.10.2.ebuild b/dev-ruby/rcairo/rcairo-1.10.2.ebuild
new file mode 100644
index 000000000000..d8b2214149f1
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.10.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.2.ebuild,v 1.1 2011/11/24 07:11:01 graaff Exp $
+
+EAPI=2
+
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18 ree18 ruby19"
+
+RUBY_FAKEGEM_NAME="cairo"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+
+IUSE=""
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg]"
+
+ruby_add_bdepend "
+	dev-ruby/pkg-config
+	dev-ruby/ruby-glib2
+	test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+each_ruby_configure() {
+	${RUBY} -Cext/cairo extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake -Cext/cairo || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
+		-e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
+}
+
+each_ruby_install() {
+	each_fakegem_install
+
+	insinto $(ruby_get_hdrdir)
+	doins ext/cairo/rb_cairo.h || die "Cannot install header file."
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}