Version bump with support for cairo 1.8.10.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index 8a1ecd2d6e41..405f0d3abd72 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.41 2010/08/28 18:56:22 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.42 2010/09/18 13:57:56 graaff Exp $
+
+*rcairo-1.8.5 (18 Sep 2010)
+
+  18 Sep 2010; Hans de Graaff <graaff@gentoo.org> +rcairo-1.8.5.ebuild:
+  Version bump with support for cairo 1.8.10.
 
   28 Aug 2010; Raúl Porcel <armin76@gentoo.org> rcairo-1.8.1.ebuild:
   alpha/ia64/sparc stable wrt #329807
diff --git a/dev-ruby/rcairo/rcairo-1.8.5.ebuild b/dev-ruby/rcairo/rcairo-1.8.5.ebuild
new file mode 100644
index 000000000000..416fc98720a7
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.8.5.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.8.5.ebuild,v 1.1 2010/09/18 13:57:56 graaff Exp $
+
+EAPI=2
+
+# ruby19 → fails, and even crashes Ruby
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-fakegem
+
+IUSE="svg"
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+SRC_URI="mirror://rubygems/cairo-${PV}.gem"
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
+
+# force identical svg dependency between the two so that you're forced
+# to rebuild this when changing it on cairo, this is because we cannot
+# enable/disable svg, but it'll follow what the original cairo
+# supports.
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg=]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg=]
+	dev-util/pkgconfig"
+
+ruby_add_bdepend "test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+all_ruby_prepare() {
+	# it fails, badly, as it expects the .pc to be frozen in time,
+	# which it isn't...
+	rm test/test_pkg_config.rb || die
+
+	# fix two strange assert calls
+	sed -i \
+		-e 's:assert_true(:assert(:' \
+		-e 's:assert_false(:assert(!:' \
+		test/test_exception.rb \
+		test/test_constants.rb || die
+echo
+}
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r ./test/cairo-test-utils.rb -S \
+		testrb-2 ./test/test_*.rb \
+		|| die "tests failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}