Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key )

2 files changed, 62 insertions, 2 deletions

diff --git a/dev-ruby/coolio/ChangeLog b/dev-ruby/coolio/ChangeLog
index 9cb021f8e876..faa06bfbee24 100644
--- a/dev-ruby/coolio/ChangeLog
+++ b/dev-ruby/coolio/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/coolio
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/coolio/ChangeLog,v 1.7 2013/11/05 00:56:41 mrueg Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/coolio/ChangeLog,v 1.8 2014/02/23 16:05:16 mrueg Exp $
+
+*coolio-1.2.1 (23 Feb 2014)
+
+  23 Feb 2014; Manuel Rüger <mrueg@gentoo.org> +coolio-1.2.1.ebuild:
+  Version bump.
 
 *coolio-1.2.0-r1 (05 Nov 2013)
 
diff --git a/dev-ruby/coolio/coolio-1.2.1.ebuild b/dev-ruby/coolio/coolio-1.2.1.ebuild
new file mode 100644
index 000000000000..a9d8e0c16708
--- /dev/null
+++ b/dev-ruby/coolio/coolio-1.2.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/coolio/coolio-1.2.1.ebuild,v 1.1 2014/02/23 16:05:16 mrueg Exp $
+
+EAPI=5
+
+# iobuffer: -jruby -rbx
+USE_RUBY="ruby18 ruby19 ruby20"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+RUBY_FAKEGEM_NAME="cool.io"
+
+RUBY_FAKEGEM_GEMSPEC="cool.io.gemspec"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A high performance event framework for Ruby which uses the libev C library"
+HOMEPAGE="http://coolio.github.com/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-libs/libev"
+RDEPEND="${DEPEND}"
+
+RUBY_PATCHES=( "${PN}-1.1.0-libev.patch" "${PN}-1.1.0-rubyio.patch" )
+
+ruby_add_rdepend ">=dev-ruby/iobuffer-1"
+
+all_ruby_prepare() {
+	rm -r Gemfile* ext/libev ext/cool.io/libev.c lib/.gitignore || die
+
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+	sed -i -e '28i  s.add_dependency "iobuffer"' ${RUBY_FAKEGEM_GEMSPEC} || die
+	sed -i -e '/git ls-files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Remove specs that require network connectivity
+	rm spec/dns_spec.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/cool.io extconf.rb || die
+	${RUBY} -Cext/http11_client extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/cool.io
+	cp ext/cool.io/cool.io_ext$(get_modname) lib/ || die
+
+	emake V=1 -Cext/http11_client
+	cp ext/http11_client/http11_client$(get_modname) lib/ || die
+}