Version bump wrt #191755 with fixed emacs support wrt #191764.

(Portage version: 2.1.3.9)

4 files changed, 72 insertions, 1 deletions

diff --git a/dev-util/desktop-file-utils/ChangeLog b/dev-util/desktop-file-utils/ChangeLog
index 4715d787f134..48542f536fc5 100644
--- a/dev-util/desktop-file-utils/ChangeLog
+++ b/dev-util/desktop-file-utils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/desktop-file-utils
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/ChangeLog,v 1.57 2007/07/21 19:59:04 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/ChangeLog,v 1.58 2007/09/09 15:01:11 drac Exp $
+
+*desktop-file-utils-0.14 (09 Sep 2007)
+
+  09 Sep 2007; Samuli Suominen <drac@gentoo.org>
+  +files/50desktop-file-utils-gentoo.el, +desktop-file-utils-0.14.ebuild:
+  Version bump wrt #191755 with fixed emacs support wrt #191764.
 
 *desktop-file-utils-0.13 (21 Jul 2007)
 
diff --git a/dev-util/desktop-file-utils/desktop-file-utils-0.14.ebuild b/dev-util/desktop-file-utils/desktop-file-utils-0.14.ebuild
new file mode 100644
index 000000000000..cafcb80fe84b
--- /dev/null
+++ b/dev-util/desktop-file-utils/desktop-file-utils-0.14.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/desktop-file-utils-0.14.ebuild,v 1.1 2007/09/09 15:01:11 drac Exp $
+
+inherit eutils elisp-common
+
+DESCRIPTION="Command line utilities to work with desktop menu entries"
+HOMEPAGE="http://www.freedesktop.org/software/desktop-file-utils"
+SRC_URI="http://www.freedesktop.org/software/${PN}/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="emacs"
+
+RDEPEND=">=dev-libs/glib-2.6
+	emacs? ( virtual/emacs )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+SITEFILE=50${PN}-gentoo.el
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i -e 's:misc::' Makefile.in
+	# add manpages from bug 85354
+	epatch "${FILESDIR}"/${PN}-0.10-man.patch
+}
+
+src_compile() {
+	econf
+	emake || die "emake failed."
+	use emacs && elisp-compile misc/desktop-entry-mode.el
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+
+	if use emacs; then
+		elisp-install ${PN} misc/*.el misc/*.elc || die "elisp-install failed."
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README
+	doman man/*
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/dev-util/desktop-file-utils/files/50desktop-file-utils-gentoo.el b/dev-util/desktop-file-utils/files/50desktop-file-utils-gentoo.el
new file mode 100644
index 000000000000..dd192d698bdc
--- /dev/null
+++ b/dev-util/desktop-file-utils/files/50desktop-file-utils-gentoo.el
@@ -0,0 +1,7 @@
+
+;; desktop-file-utils site initialisation
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'desktop-entry-mode "desktop-entry-mode" "Desktop Entry mode" t)
+(add-to-list 'auto-mode-alist
+ '("\\.desktop\\(\\.in\\)?$" . desktop-entry-mode))
+(add-hook 'desktop-entry-mode-hook 'turn-on-font-lock)
diff --git a/dev-util/desktop-file-utils/files/digest-desktop-file-utils-0.14 b/dev-util/desktop-file-utils/files/digest-desktop-file-utils-0.14
new file mode 100644
index 000000000000..fd5b253a42cd
--- /dev/null
+++ b/dev-util/desktop-file-utils/files/digest-desktop-file-utils-0.14
@@ -0,0 +1,3 @@
+MD5 e0b5057a4e3166f34635ac6f27c712c0 desktop-file-utils-0.14.tar.gz 348743
+RMD160 932ac0439188efe6b84ea61561b17f07f0f2a0d6 desktop-file-utils-0.14.tar.gz 348743
+SHA256 97856d2621d4e3273340b7f1172c2e074c74263629b05bde0f0f077425ec0699 desktop-file-utils-0.14.tar.gz 348743