Bump to 1.1.8 from the gnome overlay. Adding myself as co-maintainer (acked by leio). Update project homepage and SRC_URI. Notable changes: uses the perf counter interface introduced in kernel 2.6.31 instead of building its own kernel module; adds a command-line interface.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

5 files changed, 91 insertions, 9 deletions

diff --git a/dev-util/sysprof/ChangeLog b/dev-util/sysprof/ChangeLog
index fbd3ad7005cc..dfbf0a6753e0 100644
--- a/dev-util/sysprof/ChangeLog
+++ b/dev-util/sysprof/ChangeLog
@@ -1,6 +1,16 @@
 # ChangeLog for dev-util/sysprof
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/ChangeLog,v 1.16 2011/03/27 13:09:22 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/ChangeLog,v 1.17 2011/10/30 18:43:17 tetromino Exp $
+
+*sysprof-1.1.8 (30 Oct 2011)
+
+  30 Oct 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  sysprof-1.0.12.ebuild, sysprof-1.0.12-r1.ebuild, +sysprof-1.1.8.ebuild,
+  metadata.xml:
+  Bump to 1.1.8 from the gnome overlay. Adding myself as co-maintainer (acked
+  by leio). Update project homepage and SRC_URI.
+  Notable changes: uses the perf counter interface introduced in kernel 2.6.31
+  instead of building its own kernel module; adds a command-line interface.
 
   27 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org> sysprof-1.0.12.ebuild,
   sysprof-1.0.12-r1.ebuild:
diff --git a/dev-util/sysprof/metadata.xml b/dev-util/sysprof/metadata.xml
index a0aa3980fe63..63cef7d6c573 100644
--- a/dev-util/sysprof/metadata.xml
+++ b/dev-util/sysprof/metadata.xml
@@ -4,9 +4,13 @@
 <maintainer>
 <email>leio@gentoo.org</email>
 </maintainer>
+<maintainer>
+<email>tetromino@gentoo.org</email>
+<name>Alexandre Rostovtsev</name>
+</maintainer>
 <longdescription lang="en">
-	Sysprof is a sampling CPU profiler for Linux that uses a kernel module
-	to profile the entire system, not just a single application.
+	Sysprof is a sampling CPU profiler for Linux that profiles the entire system,
+	not just a single application.
 	Sysprof handles shared libraries and applications do not need to be recompiled.
 	In fact they don't even have to be restarted.
 </longdescription>
diff --git a/dev-util/sysprof/sysprof-1.0.12-r1.ebuild b/dev-util/sysprof/sysprof-1.0.12-r1.ebuild
index 40278b747336..722fb346e071 100644
--- a/dev-util/sysprof/sysprof-1.0.12-r1.ebuild
+++ b/dev-util/sysprof/sysprof-1.0.12-r1.ebuild
@@ -1,14 +1,14 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/sysprof-1.0.12-r1.ebuild,v 1.2 2011/03/27 13:09:22 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/sysprof-1.0.12-r1.ebuild,v 1.3 2011/10/30 18:43:18 tetromino Exp $
 
 EAPI="1"
 
 inherit eutils linux-mod
 
 DESCRIPTION="System-wide Linux Profiler"
-HOMEPAGE="http://www.daimi.au.dk/~sandmann/sysprof/"
-SRC_URI="http://www.daimi.au.dk/~sandmann/sysprof/${P}.tar.gz"
+HOMEPAGE="http://sysprof.com/"
+SRC_URI="http://sysprof.com/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
diff --git a/dev-util/sysprof/sysprof-1.0.12.ebuild b/dev-util/sysprof/sysprof-1.0.12.ebuild
index f15ec0218e07..7ebaa5e25623 100644
--- a/dev-util/sysprof/sysprof-1.0.12.ebuild
+++ b/dev-util/sysprof/sysprof-1.0.12.ebuild
@@ -1,14 +1,14 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/sysprof-1.0.12.ebuild,v 1.3 2011/03/27 13:09:22 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/sysprof-1.0.12.ebuild,v 1.4 2011/10/30 18:43:18 tetromino Exp $
 
 EAPI="1"
 
 inherit eutils linux-mod
 
 DESCRIPTION="System-wide Linux Profiler"
-HOMEPAGE="http://www.daimi.au.dk/~sandmann/sysprof/"
-SRC_URI="http://www.daimi.au.dk/~sandmann/sysprof/${P}.tar.gz"
+HOMEPAGE="http://sysprof.com/"
+SRC_URI="http://sysprof.com/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
diff --git a/dev-util/sysprof/sysprof-1.1.8.ebuild b/dev-util/sysprof/sysprof-1.1.8.ebuild
new file mode 100644
index 000000000000..93d89e97971c
--- /dev/null
+++ b/dev-util/sysprof/sysprof-1.1.8.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysprof/sysprof-1.1.8.ebuild,v 1.1 2011/10/30 18:43:18 tetromino Exp $
+
+EAPI="4"
+
+inherit gnome2-utils eutils linux-info
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+SRC_URI="http://sysprof.com/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.6:2
+	>=x11-libs/gtk+-2.6:2
+	x11-libs/pango
+	>=gnome-base/libglade-2:2.0"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9"
+
+DOCS="AUTHORS NEWS README TODO" # ChangeLog is empty
+
+pkg_pretend() {
+	kernel_is -ge 2 6 31 && return
+	die "Sysprof will not work with a kernel version less than 2.6.31"
+}
+
+src_install() {
+	default
+
+	# Install udev rules in the proper place
+	mkdir -p "${D}/lib/udev/rules.d" || die
+	mv "${D}/etc/udev/rules.d/"* "${D}/lib/udev/rules.d/" || die
+	rm -rf "${D}/etc/udev/rules.d/"
+
+	# Insert icons in the proper place
+	for i in 16 24 32 48; do
+		insinto "/usr/share/icons/hicolor/${i}x${i}/apps"
+		newins "${S}/sysprof-icon-${i}.png" sysprof.png
+		rm "${D}/usr/share/pixmaps/sysprof-icon-${i}.png" || die "rm $i failed!"
+	done
+	make_desktop_entry sysprof Sysprof sysprof
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}