Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 77 insertions, 2 deletions

diff --git a/dev-util/debhelper/ChangeLog b/dev-util/debhelper/ChangeLog
index 8e546560b2cf..4b819ac3187e 100644
--- a/dev-util/debhelper/ChangeLog
+++ b/dev-util/debhelper/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/debhelper
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.97 2013/12/28 13:25:47 jer Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.98 2014/02/28 16:14:15 jer Exp $
+
+*debhelper-9.20140227 (28 Feb 2014)
+
+  28 Feb 2014; Jeroen Roovers <jer@gentoo.org> +debhelper-9.20140227.ebuild:
+  Version bump.
 
 *debhelper-9.20131227 (28 Dec 2013)
 
diff --git a/dev-util/debhelper/debhelper-9.20140227.ebuild b/dev-util/debhelper/debhelper-9.20140227.ebuild
new file mode 100644
index 000000000000..a96c1c3ba167
--- /dev/null
+++ b/dev-util/debhelper/debhelper-9.20140227.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/debhelper-9.20140227.ebuild,v 1.1 2014/02/28 16:14:15 jer Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Collection of programs that can be used to automate common tasks in debian/rules"
+HOMEPAGE="http://packages.qa.debian.org/d/debhelper.html http://joeyh.name/code/debhelper/"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux"
+IUSE="test"
+DH_LINGUAS=( de es fr )
+IUSE+=" ${DH_LINGUAS[@]/#/linguas_}"
+
+NLS_DEPEND=$(
+	printf "linguas_%s? ( >=app-text/po4a-0.24 )\n" ${DH_LINGUAS[@]}
+)
+
+RDEPEND="
+	>=dev-lang/perl-5.10
+	>=app-arch/dpkg-1.17
+	dev-perl/TimeDate
+	virtual/perl-Getopt-Long
+"
+DEPEND="${RDEPEND}
+	${NLS_DEPEND}
+	test? ( dev-perl/Test-Pod )
+"
+
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	tc-export CC
+
+	local LANGS="" USE_NLS=no lingua
+	for lingua in ${DH_LINGUAS[@]}; do
+		if use linguas_${lingua}; then
+			LANGS+=" ${lingua}"
+			USE_NLS=yes
+		fi
+	done
+
+	emake USE_NLS="${USE_NLS}" LANGS="${LANGS}" build
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+	dodoc doc/* debian/changelog
+	docinto examples
+	dodoc examples/*
+	local lingua
+	for manfile in *.1 *.7 ; do
+		for lingua in ${DH_LINGUAS[@]}; do
+			case ${manfile} in
+				*.${lingua}.?)
+					use linguas_${lingua} \
+						&& cp ${manfile} "${T}"/${manfile/.${lingua}/} \
+						&& doman -i18n=${lingua} "${T}"/${manfile/.${lingua}/}
+					;;
+				*)
+					doman ${manfile}
+					;;
+			esac
+		done
+	done
+}