Add tuxanci-0.21.0. Fixes bug #172153.

(Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64)

1 files changed, 58 insertions, 0 deletions

diff --git a/games-arcade/tuxanci/tuxanci-0.21.0.ebuild b/games-arcade/tuxanci/tuxanci-0.21.0.ebuild
new file mode 100644
index 000000000000..1963a2e0ebc8
--- /dev/null
+++ b/games-arcade/tuxanci/tuxanci-0.21.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/tuxanci/tuxanci-0.21.0.ebuild,v 1.1 2008/10/27 07:37:04 scarabeus Exp $
+
+EAPI="2"
+
+inherit games cmake-utils
+
+DESCRIPTION="Tuxanci is first cushion shooter inspired by game Bulanci."
+HOMEPAGE="http://www.tuxanci.org/"
+SRC_URI="http://download.${PN}.org/${P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug dedicated nls"
+# alsa is used only when building client
+
+RDEPEND="!dedicated? (
+			>=media-libs/libsdl-1.2.10
+			>=media-libs/sdl-ttf-2.0.7
+			>=media-libs/sdl-image-1.2.6-r1
+			alsa? (
+				>=media-libs/sdl-mixer-1.2.7
+			)
+		)
+	dev-libs/zziplib"
+DEPEND="${RDEPEND}
+	>=dev-util/cmake-2.6.0
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local mycmakeargs
+	use alsa || mycmakeargs="${mycmakeargs} -DNO_Audio=1"
+	use debug && mycmakeargs="${mycmakeargs} -DDebug=1"
+	use dedicated && mycmakeargs="${mycmakeargs} -DServer=1"
+	use nls && mycmakeargs="${mycmakeargs} -DNLS=1"
+	# This cant be quoted due to cmake nature.
+	# Read as: quote it and it wont compile.
+	mycmakeargs="${mycmakeargs} -DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
+		-DCMAKE_DATA_PATH=${GAMES_DATADIR}
+		-DCMAKE_LOCALE_PATH=${GAMES_DATADIR_BASE}/locale/
+		-DCMAKE_DOC_PATH=${GAMES_DATADIR_BASE}/doc/
+		-DCMAKE_ETC_PATH=${GAMES_SYSCONFDIR} -DLIB_INSTALL_DIR=$(games_get_libdir)"
+	cmake-utils_src_configure
+}
+
+src_install() {
+	local MY_PN
+	use dedicated && MY_PN=${PN}-server || MY_PN=${PN}
+
+	cmake-utils_src_install
+	dosym "${GAMES_BINDIR}"/${MY_PN}-${PV} "${GAMES_BINDIR}"/${MY_PN}
+	doicon data/${PN}.svg
+	# we compile our desktop file
+	domenu data/${PN}.desktop
+	prepgamesdirs
+}