fix engine detection when python3 is eselected wrt #487706

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

1 files changed, 76 insertions, 0 deletions

diff --git a/games-board/pychess/pychess-0.10.1-r2.ebuild b/games-board/pychess/pychess-0.10.1-r2.ebuild
new file mode 100644
index 000000000000..f5365c72cfae
--- /dev/null
+++ b/games-board/pychess/pychess-0.10.1-r2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/pychess/pychess-0.10.1-r2.ebuild,v 1.1 2013/10/22 18:16:51 hasufell Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_6 python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit fdo-mime gnome2-utils distutils-r1 games
+
+DESCRIPTION="A chess client for Gnome"
+HOMEPAGE="http://pychess.googlepages.com/home"
+SRC_URI="http://pychess.googlecode.com/files/${P/_/}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gstreamer"
+
+DEPEND="dev-python/librsvg-python
+	dev-python/pycairo
+	dev-python/pygobject:2
+	dev-python/pygtk
+	dev-python/pygtksourceview
+	gstreamer? ( dev-python/gst-python )
+	dev-python/gconf-python
+	x11-themes/gnome-icon-theme"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/${P}-python.patch )
+
+S=${WORKDIR}/${P/_/}
+
+python_install() {
+	distutils-r1_python_install --install-scripts="${GAMES_BINDIR}"
+
+	# bug 487706
+	sed -i \
+		-e "s/@PYTHON@/${EPYTHON}/" \
+		"${ED%/}/$(python_get_sitedir)"/${PN}/Players/engineNest.py || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc AUTHORS README
+	prepgamesdirs
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}