revbump: bump eapi, update icon cache, respect CFLAGS wrt #453150

(Portage version: 2.2.0_alpha159/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

3 files changed, 96 insertions, 4 deletions

diff --git a/games-board/spider/ChangeLog b/games-board/spider/ChangeLog
index 7a4be9d01f62..d8ad8bb662bb 100644
--- a/games-board/spider/ChangeLog
+++ b/games-board/spider/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for games-board/spider
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/spider/ChangeLog,v 1.6 2012/12/11 06:34:02 ulm Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/spider/ChangeLog,v 1.7 2013/01/24 00:01:58 hasufell Exp $
+
+*spider-1.2_p4-r1 (23 Jan 2013)
+
+  23 Jan 2013; Julian Ospald <hasufell@gentoo.org> spider-1.2_p4.ebuild,
+  +spider-1.2_p4-r1.ebuild:
+  fix copyright header
+  revbump: bump eapi, update icon cache, respect CFLAGS wrt #453150
 
   11 Dec 2012; Ulrich Müller <ulm@gentoo.org> spider-1.2_p4.ebuild:
   Update LICENSE, see copyright.h file.
diff --git a/games-board/spider/spider-1.2_p4-r1.ebuild b/games-board/spider/spider-1.2_p4-r1.ebuild
new file mode 100644
index 000000000000..465b89b21f93
--- /dev/null
+++ b/games-board/spider/spider-1.2_p4-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/spider/spider-1.2_p4-r1.ebuild,v 1.1 2013/01/24 00:01:58 hasufell Exp $
+
+EAPI=5
+inherit eutils gnome2-utils games
+
+MY_P="${P%%_*}"
+MY_P="${MY_P/-/_}"
+DEB_V="${P##*_p}"
+
+DESCRIPTION="Spider Solitaire"
+HOMEPAGE="http://packages.debian.org/stable/games/spider"
+SRC_URI="mirror://debian/pool/main/s/spider/${MY_P}.orig.tar.gz
+	mirror://debian/pool/main/s/spider/${MY_P}-${DEB_V}.diff.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="athena"
+
+RDEPEND="x11-libs/libXext
+	athena? ( x11-libs/libXaw )
+	x11-libs/libXmu
+	x11-libs/libXt"
+DEPEND="${RDEPEND}
+	x11-misc/imake
+	x11-proto/xproto"
+
+S=${WORKDIR}/${MY_P/_/-}.orig
+
+src_prepare() {
+	epatch "${WORKDIR}"/${MY_P}-${DEB_V}.diff
+	sed -i \
+		-e '/MKDIRHIER/s:/X11::' \
+		*Imakefile \
+		|| die "sed failed"
+	rm Makefile
+}
+
+src_configure() {
+	imake \
+		-DUseInstalled \
+		-DSmallCards=NO \
+		-DRoundCards \
+		$(use athena && echo "-DCompileXAW=YES" || echo "-DCompileXlibOnly=YES") \
+		-I/usr/lib/X11/config \
+		|| die "imake failed"
+	sed -i \
+		-e '/CC = /d' \
+		-e "s/CDEBUGFLAGS = .*$/CDEBUGFLAGS = ${CFLAGS}/" \
+		-e '/LDOPTIONS = /s/$/$(LDFLAGS)/' \
+		Makefile \
+		|| die "sed failed"
+}
+
+src_install() {
+	emake -j1 \
+		DESTDIR="${D}" \
+		BINDIR="${GAMES_BINDIR}" \
+		MANSUFFIX="6" \
+		MANDIR="/usr/share/man/man6" \
+		HELPDIR="/usr/share/doc/${PF}" \
+		install install.doc install.man
+
+	dodoc README* ChangeLog
+	newicon icons/Spider.png ${PN}.png
+	newicon -s 32 icons/Spider32x32.png ${PN}.png
+	make_desktop_entry spider Spider
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-board/spider/spider-1.2_p4.ebuild b/games-board/spider/spider-1.2_p4.ebuild
index 94909a9bb22f..d57b4feded92 100644
--- a/games-board/spider/spider-1.2_p4.ebuild
+++ b/games-board/spider/spider-1.2_p4.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/spider/spider-1.2_p4.ebuild,v 1.6 2012/12/11 06:34:02 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/spider/spider-1.2_p4.ebuild,v 1.7 2013/01/24 00:01:58 hasufell Exp $
 
 EAPI=2
 inherit eutils games