Version bump, bug #288624

(Portage version: 2.2_rc46/cvs/Linux x86_64)

2 files changed, 91 insertions, 1 deletions

diff --git a/games-fps/alienarena/ChangeLog b/games-fps/alienarena/ChangeLog
index 277458034e0a..87c19e0291a9 100644
--- a/games-fps/alienarena/ChangeLog
+++ b/games-fps/alienarena/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-fps/alienarena
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.14 2009/06/24 18:14:01 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.15 2009/10/14 18:34:20 nyhm Exp $
+
+*alienarena-20091006 (14 Oct 2009)
+
+  14 Oct 2009; Tristan Heaven <nyhm@gentoo.org> +alienarena-20091006.ebuild:
+  Version bump, bug #288624
 
   24 Jun 2009; Michael Sterrett <mr_bones_@gentoo.org>
   alienarena-20090616.ebuild:
diff --git a/games-fps/alienarena/alienarena-20091006.ebuild b/games-fps/alienarena/alienarena-20091006.ebuild
new file mode 100644
index 000000000000..79af0208f969
--- /dev/null
+++ b/games-fps/alienarena/alienarena-20091006.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/alienarena-20091006.ebuild,v 1.1 2009/10/14 18:34:20 nyhm Exp $
+
+EAPI=2
+inherit eutils games
+
+MY_PN=alienarena7_31
+DESCRIPTION="Fast-paced multiplayer deathmatch game"
+HOMEPAGE="http://red.planetarena.org/"
+SRC_URI="http://icculus.org/${PN}/Files/${PN}-linux${PV}.zip"
+
+LICENSE="GPL-2 free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated opengl"
+
+UIRDEPEND="media-libs/jpeg
+	media-libs/openal
+	media-libs/libvorbis
+	virtual/glu
+	virtual/opengl
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm"
+RDEPEND="opengl? ( ${UIRDEPEND} )
+	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )
+	net-misc/curl"
+UIDEPEND="x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto"
+DEPEND="${RDEPEND}
+	opengl? ( ${UIDEPEND} )
+	!opengl? ( !dedicated? ( ${UIDEPEND} ) )
+	dev-util/pkgconfig
+	app-arch/unzip"
+
+S=${WORKDIR}/${MY_PN}/source
+
+src_prepare() {
+	rm -f ../*/*.so
+	sed -i \
+		-e 's:\($(SHLIBLDFLAGS)\):$(LDFLAGS) \1:' \
+		Makefile \
+		|| die "sed failed"
+}
+
+src_compile() {
+	emake \
+		ARCH="unknown" \
+		OSTYPE="linux" \
+		OPTIMIZED_CFLAGS=no \
+		WITH_DATADIR=yes \
+		WITH_LIBDIR=yes \
+		DATADIR="${GAMES_DATADIR}"/${PN} \
+		LIBDIR="$(games_get_libdir)"/${PN} \
+		$(use opengl && ! use dedicated && echo BUILD=CLIENT) \
+		$(! use opengl && use dedicated && echo BUILD=DEDICATED) \
+		$(use opengl && use dedicated && echo BUILD=ALL) \
+		$(use opengl || use dedicated || echo BUILD=CLIENT) \
+		|| die "emake failed"
+}
+
+src_install() {
+	cd release
+	exeinto "$(games_get_libdir)"/${PN}
+	doexe game.so || die "doexe failed"
+	dosym . "$(games_get_libdir)"/${PN}/arena
+	dosym . "$(games_get_libdir)"/${PN}/data1
+
+	if use opengl || ! use dedicated ; then
+		newgamesbin crx ${PN} || die "newgamesbin crx failed"
+		make_desktop_entry ${PN} "Alien Arena"
+	fi
+
+	if use dedicated ; then
+		newgamesbin crded ${PN}-ded || die "newgamesbin crded failed"
+	fi
+
+	cd "${WORKDIR}"/${MY_PN}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r arena botinfo data1 || die "doins failed"
+	newicon aa.png ${PN}.png || die "newicon failed"
+	dodoc docs/README.txt
+
+	prepgamesdirs
+}