Version bump. Ebuild by Paul Bredbury <brebs@sent.com> and edit by me. Closing bug #136979.

(Portage version: 2.1.1_pre1-r2)

4 files changed, 183 insertions, 3 deletions

diff --git a/games-fps/nexuiz/ChangeLog b/games-fps/nexuiz/ChangeLog
index d0d01975fcff..9870c7eccdbf 100644
--- a/games-fps/nexuiz/ChangeLog
+++ b/games-fps/nexuiz/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for games-fps/nexuiz
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.9 2006/06/11 10:01:27 blubb Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.10 2006/06/27 19:09:17 wolf31o2 Exp $
+
+*nexuiz-2.0 (27 Jun 2006)
+
+  27 Jun 2006; Chris Gianelloni <wolf31o2@gentoo.org> -nexuiz-1.2.1.ebuild,
+  nexuiz-1.5.ebuild, +nexuiz-2.0.ebuild:
+  Version bump. Ebuild by Paul Bredbury <brebs@sent.com> and edit by me.
+  Closing bug #136979.
 
   11 Jun 2006; Simon Stelling <blubb@gentoo.org> nexuiz-1.5.ebuild:
   marking stable on amd64 and changing description per bug 134694
diff --git a/games-fps/nexuiz/files/digest-nexuiz-2.0 b/games-fps/nexuiz/files/digest-nexuiz-2.0
new file mode 100644
index 000000000000..f1943a384430
--- /dev/null
+++ b/games-fps/nexuiz/files/digest-nexuiz-2.0
@@ -0,0 +1,3 @@
+MD5 3cabe44472a848b870685b225b1086c3 nexuiz-20.zip 199962978
+RMD160 d08f4288b2d29c605fb260f75c9e90682617ccaa nexuiz-20.zip 199962978
+SHA256 ec530582a8050ddc6f270446994e83a24aa8b664f136132f5764f9a9aa192bf1 nexuiz-20.zip 199962978
diff --git a/games-fps/nexuiz/nexuiz-1.5.ebuild b/games-fps/nexuiz/nexuiz-1.5.ebuild
index ce3fee4dfb73..9c25e84bc99a 100644
--- a/games-fps/nexuiz/nexuiz-1.5.ebuild
+++ b/games-fps/nexuiz/nexuiz-1.5.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2006 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-1.5.ebuild,v 1.6 2006/06/11 10:01:27 blubb Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-1.5.ebuild,v 1.7 2006/06/27 19:09:17 wolf31o2 Exp $
 
 inherit eutils games
 
@@ -12,7 +12,7 @@ HOMEPAGE="http://www.nexuiz.com"
 SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.zip"
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~ppc ~x86"
+KEYWORDS="amd64 ~ppc x86"
 IUSE="dedicated opengl sdl"
 
 UIDEPEND="media-libs/alsa-lib
diff --git a/games-fps/nexuiz/nexuiz-2.0.ebuild b/games-fps/nexuiz/nexuiz-2.0.ebuild
new file mode 100644
index 000000000000..5bf7593b0dcd
--- /dev/null
+++ b/games-fps/nexuiz/nexuiz-2.0.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-2.0.ebuild,v 1.1 2006/06/27 19:09:17 wolf31o2 Exp $
+
+inherit eutils flag-o-matic games
+
+MY_PV=${PV//./}
+MY_PN="Nexuiz"
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.nexuiz.com"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip
+	http://www.alientrap.org/Releases/${MY_P}.zip"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dedicated opengl oss sdl"
+
+UIRDEPEND="alsa? ( media-libs/alsa-lib )
+	media-libs/libogg
+	media-libs/libvorbis
+	|| (
+		(
+			x11-libs/libX11
+			x11-libs/libXau
+			x11-libs/libXdmcp
+			x11-libs/libXext
+			x11-libs/libXxf86dga
+			x11-libs/libXxf86vm )
+		virtual/x11 )"
+UIDEPEND="|| (
+	(
+		x11-proto/xextproto
+		x11-proto/xf86dgaproto
+		x11-proto/xf86vidmodeproto
+		x11-proto/xproto )
+	virtual/x11 )"
+RDEPEND="media-libs/jpeg
+	sys-libs/glibc
+	sys-libs/zlib
+	sdl? (
+		media-libs/libsdl
+		${UIRDEPEND} )
+	opengl? (
+		virtual/opengl
+		${UIRDEPEND} )
+	!dedicated? (
+		!sdl? (
+			!opengl? (
+				virtual/opengl
+				${UIRDEPEND} ) ) )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	app-arch/unzip
+	sdl? ( ${UIDEPEND} )
+	opengl? ( ${UIRDEPEND} )
+	!dedicated? ( !sdl? ( !opengl? ( ${UIRDEPEND} ) ) )"
+
+S=${WORKDIR}/darkplaces
+# This is the right dir, so that e.g. "darkplaces -game nexuiz" will work
+dir=${GAMES_DATADIR}/quake1
+exe=${PN}
+
+default_client() {
+	if use opengl || $( ! use dedicated && ! use sdl ) ; then
+		# Build default client
+		return 0
+	fi
+	return 1
+}
+
+pkg_setup() {
+	games_pkg_setup
+
+	if default_client && ! use opengl ; then
+		einfo "Defaulting to OpenGL client"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+
+	local f
+	for f in "${MY_PN}"/sources/*.zip ; do
+		unpack ./"${f}"
+	done
+
+	rm "${MY_PN}"/Docs/server/{*_mac.*,*.bat}
+
+	cd "${S}"
+	# Make the game automatically look in the correct data directory
+	sed -i fs.c \
+		-e "s:strcpy(fs_basedir, \"\"):strcpy(fs_basedir, \"${dir}\"):" \
+		-e "s:gamedirname1:\"${PN}\":" \
+		|| die "sed fs.c failed"
+
+	# Only additional CFLAGS optimization is the -march flag
+	local march=$(get-flag -march)
+	sed -i makefile.inc \
+		-e '/^CC=/d' \
+		-e "s:-lasound:$(pkg-config --libs alsa):" \
+		-e "s:CPUOPTIMIZATIONS=:CPUOPTIMIZATIONS=${march}:" \
+		-e "s:strip:#strip:" \
+		|| die "sed makefile.inc failed"
+
+	# Reduce SDL audio buffer, to fix latency
+	sed -i "s:requested->speed / 20.0:512:" snd_sdl.c \
+		|| die "sed snd_sdl.c failed"
+
+	# Default sound is alsa.
+	if ! use alsa ; then
+		if use oss ; then
+			sed -i "s:DEFAULT_SNDAPI=ALSA:DEFAULT_SNDAPI=OSS:" makefile \
+				|| die "sed oss failed"
+		else
+			sed -i "s:DEFAULT_SNDAPI=ALSA:DEFAULT_SNDAPI=NULL:" makefile \
+				|| die "sed null failed"
+		fi
+	fi
+}
+
+src_compile() {
+	if default_client ; then
+		emake cl-${PN} || die "emake cl-${PN} failed"
+	fi
+
+	if use sdl ; then
+		emake sdl-${PN} || die "emake sdl-${PN} failed"
+	fi
+
+	if use dedicated ; then
+		emake sv-${PN} || die "emake sv-${PN} failed"
+	fi
+}
+
+src_install() {
+	if default_client || use sdl ; then
+		newicon darkplaces72x72.png ${PN}.png
+	fi
+
+	if default_client ; then
+		newgamesbin ${PN}-glx ${PN} \
+			|| die "newgamesbin opengl failed"
+		make_desktop_entry ${PN} Nexuiz ${PN}.png
+	fi
+
+	if use sdl ; then
+		dogamesbin ${PN}-sdl \
+			|| die "dogamesbin sdl failed"
+		make_desktop_entry ${PN}-sdl "Nexuiz (SDL)" ${PN}.png
+	fi
+
+	if use dedicated ; then
+		newgamesbin ${PN}-dedicated ${PN}-ded \
+			|| die "newgamesbin ded failed"
+		games_make_wrapper ${PN}-ded ./${PN}-ded "${dir}"
+	fi
+
+	cd "${WORKDIR}/${MY_PN}"
+	insinto "${dir}/${PN}"
+	doins -r data/* || die "doins data failed"
+
+	dodoc Docs/*.txt
+	dohtml Docs/*.{htm,html}
+	docinto server
+	dodoc Docs/server/*
+
+	prepgamesdirs
+}