version bump (bug #299406) with development from Widget and ssuominen

(Portage version: 2.1.7.16/cvs/Linux i686)

3 files changed, 111 insertions, 2 deletions

diff --git a/games-roguelike/angband/ChangeLog b/games-roguelike/angband/ChangeLog
index dcfd6227975c..e90e7917c756 100644
--- a/games-roguelike/angband/ChangeLog
+++ b/games-roguelike/angband/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-roguelike/angband
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.29 2010/01/07 22:04:12 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.30 2010/02/16 22:25:13 mr_bones_ Exp $
+
+*angband-3.1.2_p2 (16 Feb 2010)
+
+  16 Feb 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +angband-3.1.2_p2.ebuild:
+  version bump (bug #299406) with development from Widget and ssuominen
 
   07 Jan 2010; Joseph Jezak <josejx@gentoo.org> angband-3.0.9e.ebuild:
   Marked ppc stable for bug #294528.
diff --git a/games-roguelike/angband/angband-3.1.2_p2.ebuild b/games-roguelike/angband/angband-3.1.2_p2.ebuild
new file mode 100644
index 000000000000..5e0cef5052f1
--- /dev/null
+++ b/games-roguelike/angband/angband-3.1.2_p2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/angband-3.1.2_p2.ebuild,v 1.1 2010/02/16 22:25:13 mr_bones_ Exp $
+
+EAPI=2
+inherit versionator games
+
+MAJOR_PV=$(get_version_component_range 1-2)
+MY_P=${P/_p/v}
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="http://rephial.org/"
+SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${MY_P}-src.tar.gz"
+
+LICENSE="Moria"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="gtk ncurses sdl +sound X"
+
+RDEPEND="gtk? ( gnome-base/libglade
+	   x11-libs/pango
+	   x11-libs/gtk+:2
+	   dev-libs/glib:2 )
+	X? ( x11-libs/libSM
+		 x11-libs/libX11 )
+	!ncurses? ( !X? ( !sdl? ( !gtk? ( sys-libs/ncurses ) ) ) )
+	sdl? ( media-libs/libsdl[video,X]
+		media-libs/sdl-ttf
+		media-libs/sdl-image
+		sound? ( media-libs/sdl-mixer
+			media-libs/libsdl[audio] ) )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local myconf
+
+	if use sdl; then
+		myconf="$(use_enable sound sdl-mixer)"
+	else
+		myconf="--disable-sdl-mixer"
+	fi
+
+	econf \
+		--bindir="${GAMES_BINDIR}" \
+		--with-configpath="${GAMES_SYSCONFDIR}/${PN}" \
+		--with-libpath="${GAMES_DATADIR}/${PN}" \
+		--with-varpath="${GAMES_STATEDIR}/${PN}" \
+		--with-private-dirs \
+		$(use_enable X x11) \
+		$(use_enable gtk) \
+		$(use_enable sdl) \
+		$(use_enable ncurses curses) \
+		$( use !gtk && use !sdl && use !ncurses && use !X && \
+			echo --enable-curses) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# Edit files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
+		> "${T}"/99${PN}
+	doenvd "${T}"/99${PN} || die
+
+	dodoc changes.txt faq.txt readme.txt thanks.txt || die
+
+	# Create desktop entries if required.
+	ICON_LOC="${GAMES_DATADIR}/${PN}/xtra/icon/att-32.png"
+	if use X; then
+		make_desktop_entry "angband -mx11" "Angband (X11)" "${ICON_LOC}" || die
+	fi
+
+	if use sdl; then
+		make_desktop_entry "angband -msdl" "Angband (SDL)" "${ICON_LOC}" || die
+	fi
+
+	if use gtk; then
+		make_desktop_entry "angband -mgtk" "Angband (GTK)" "${ICON_LOC}" || die
+	fi
+
+	use ncurses || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/graf"
+	use sound || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/sound"
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	echo
+	elog "Angband now uses private savefiles instead of system-wide ones"
+	elog "This version of Angband is not compatible with the save files"
+	elog "of previous versions"
+	echo
+
+	games_pkg_postinst
+}
diff --git a/games-roguelike/angband/metadata.xml b/games-roguelike/angband/metadata.xml
index d3c2cc926f0b..b8e6986601e2 100644
--- a/games-roguelike/angband/metadata.xml
+++ b/games-roguelike/angband/metadata.xml
@@ -1,5 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>games</herd>
+	<herd>games</herd>
+	<use>
+		<flag name='sound'>Enable and install sounds</flag>
+	</use>
 </pkgmetadata>