version bump

(Portage version: 2.1.6.13/cvs/Linux i686)

2 files changed, 70 insertions, 1 deletions

diff --git a/games-strategy/wormux/ChangeLog b/games-strategy/wormux/ChangeLog
index 5005bb1df27d..ceffadb40d8e 100644
--- a/games-strategy/wormux/ChangeLog
+++ b/games-strategy/wormux/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/wormux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/wormux/ChangeLog,v 1.32 2009/07/09 05:18:10 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/wormux/ChangeLog,v 1.33 2009/09/16 21:43:51 mr_bones_ Exp $
+
+*wormux-0.8.5 (16 Sep 2009)
+
+  16 Sep 2009; Michael Sterrett <mr_bones_@gentoo.org> +wormux-0.8.5.ebuild:
+  version bump
 
 *wormux-0.8.4 (09 Jul 2009)
 
diff --git a/games-strategy/wormux/wormux-0.8.5.ebuild b/games-strategy/wormux/wormux-0.8.5.ebuild
new file mode 100644
index 000000000000..9a7a21e4166c
--- /dev/null
+++ b/games-strategy/wormux/wormux-0.8.5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/wormux/wormux-0.8.5.ebuild,v 1.1 2009/09/16 21:43:51 mr_bones_ Exp $
+
+EAPI=2
+inherit autotools eutils games
+
+DESCRIPTION="A free Worms clone"
+HOMEPAGE="http://www.wormux.org/"
+SRC_URI="http://download.gna.org/wormux/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug nls unicode"
+
+RDEPEND="media-libs/libsdl[joystick,video]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-ttf
+	media-libs/sdl-net
+	media-libs/sdl-gfx
+	media-libs/libpng
+	net-misc/curl
+	media-fonts/dejavu
+	>=dev-cpp/libxmlpp-2.6
+	nls? ( virtual/libintl )
+	unicode? ( dev-libs/fribidi )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	sed -i \
+		-e "/AX_CFLAGS_WARN_ALL/d" \
+		-e "s/-Werror//g" \
+		configure.ac \
+		|| die "sed failed"
+	sed -i \
+		-e "/xdg/d" \
+		-e "/pixmaps/d" \
+		data/Makefile.am \
+		|| die "sed failed"
+	eautoreconf
+}
+
+src_configure() {
+	egamesconf \
+		--disable-dependency-tracking \
+		--with-localedir-name=/usr/share/locale \
+		--with-datadir-name="${GAMES_DATADIR}/${PN}" \
+		--with-font-path=/usr/share/fonts/dejavu/DejaVuSans.ttf \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable unicode fribidi)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README TODO
+	doicon data/wormux.svg
+	make_desktop_entry wormux Wormux
+	prepgamesdirs
+}