Bump to 2.24.1-r1, add patch to support setup with <gnome-session-2.24, bug #246170.

(Portage version: 2.2_rc14/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

3 files changed, 90 insertions, 1 deletions

diff --git a/gnome-base/gnome-panel/ChangeLog b/gnome-base/gnome-panel/ChangeLog
index 4fe8256f1e00..0caa5410a371 100644
--- a/gnome-base/gnome-panel/ChangeLog
+++ b/gnome-base/gnome-panel/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.260 2008/11/13 19:28:23 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.261 2008/11/16 21:00:31 eva Exp $
+
+*gnome-panel-2.24.1-r1 (16 Nov 2008)
+
+  16 Nov 2008; Gilles Dartiguelongue <eva@gentoo.org>
+  +files/gnome-panel-2.24.1-logout.patch.gz, +gnome-panel-2.24.1-r1.ebuild:
+  Bump to 2.24.1-r1, add patch to support setup with <gnome-session-2.24,
+  bug #246170.
 
   13 Nov 2008; Brent Baude <ranger@gentoo.org> gnome-panel-2.22.2.ebuild:
   Marking gnome-panel-2.22.2 ppc64 stable for bug 236971
diff --git a/gnome-base/gnome-panel/files/gnome-panel-2.24.1-logout.patch.gz b/gnome-base/gnome-panel/files/gnome-panel-2.24.1-logout.patch.gz
new file mode 100644
index 000000000000..da56b16f9126
--- /dev/null
+++ b/gnome-base/gnome-panel/files/gnome-panel-2.24.1-logout.patch.gz
diff --git a/gnome-base/gnome-panel/gnome-panel-2.24.1-r1.ebuild b/gnome-base/gnome-panel/gnome-panel-2.24.1-r1.ebuild
new file mode 100644
index 000000000000..992db635d9a8
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-2.24.1-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.1-r1.ebuild,v 1.1 2008/11/16 21:00:31 eva Exp $
+
+inherit autotools gnome2
+
+DESCRIPTION="The GNOME panel"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc eds networkmanager"
+
+RDEPEND=">=gnome-base/gnome-desktop-2.12
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.16.0
+	>=x11-libs/gtk+-2.13.1
+	>=dev-libs/libgweather-2.24.1
+	dev-libs/libxml2
+	>=gnome-base/libglade-2.5
+	>=gnome-base/libgnome-2.13
+	>=gnome-base/libgnomeui-2.5.4
+	>=gnome-base/libbonoboui-2.1.1
+	>=gnome-base/orbit-2.4
+	>=x11-libs/libwnck-2.19.5
+	>=gnome-base/gconf-2.6.1
+	>=gnome-base/gnome-menus-2.11.1
+	>=gnome-base/libbonobo-2
+	gnome-base/librsvg
+	>=dev-libs/dbus-glib-0.71
+	>=sys-apps/dbus-1.1.2
+	x11-libs/libXau
+	>=x11-libs/cairo-1.0.0
+	eds? ( >=gnome-extra/evolution-data-server-1.6 )
+	networkmanager? ( >=net-misc/networkmanager-0.6 )"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.3.2
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40
+	~app-text/docbook-xml-dtd-4.1.2
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-schemas-install
+		--with-in-process-applets=clock,notification-area,wncklet
+		--disable-polkit
+		$(use_enable networkmanager network-manager)
+		$(use_enable eds)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Allow logout/shutdown without gnome-session 2.24, bug #246170
+	epatch "${FILESDIR}/${PN}-2.24.1-logout.patch.gz"
+
+	eautomake
+}
+
+pkg_postinst() {
+	local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
+	local gconftool="${ROOT}usr/bin/gconftool-2"
+
+	if [ -e "$entries" ]; then
+		einfo "setting panel gconf defaults..."
+
+		GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"
+
+		"${gconftool}" --direct --config-source \
+			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
+	fi
+
+	# Calling this late so it doesn't process the GConf schemas file we already
+	# took care of.
+	gnome2_pkg_postinst
+}