Bump to 2.26.3. Small enhancements.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 98 insertions, 1 deletions

diff --git a/gnome-base/nautilus/ChangeLog b/gnome-base/nautilus/ChangeLog
index 30e32e7601fb..7855631794a5 100644
--- a/gnome-base/nautilus/ChangeLog
+++ b/gnome-base/nautilus/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/nautilus
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.312 2009/05/18 14:40:13 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.313 2009/05/18 21:19:46 eva Exp $
+
+*nautilus-2.26.3 (18 May 2009)
+
+  18 May 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  +nautilus-2.26.3.ebuild:
+  Bump to 2.26.3. Small enhancements.
 
   18 May 2009; Jeroen Roovers <jer@gentoo.org> nautilus-2.24.2-r3.ebuild:
   Stable for HPPA (bug #269186).
diff --git a/gnome-base/nautilus/nautilus-2.26.3.ebuild b/gnome-base/nautilus/nautilus-2.26.3.ebuild
new file mode 100644
index 000000000000..616f17d48fe3
--- /dev/null
+++ b/gnome-base/nautilus/nautilus-2.26.3.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.26.3.ebuild,v 1.1 2009/05/18 21:19:46 eva Exp $
+
+EAPI="2"
+
+inherit gnome2 eutils virtualx
+
+DESCRIPTION="A file manager for the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/projects/nautilus/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="beagle doc gnome tracker xmp"
+
+# not adding gnome-base/gail because it is in gtk+
+RDEPEND=">=dev-libs/glib-2.19.0
+	>=gnome-base/gnome-desktop-2.25.5
+	>=x11-libs/pango-1.1.2
+	>=x11-libs/gtk+-2.16.0
+	>=dev-libs/libxml2-2.4.7
+	>=media-libs/libexif-0.5.12
+	>=gnome-base/gconf-2.0
+	>=gnome-base/gvfs-0.1.2
+	dev-libs/libunique
+	dev-libs/dbus-glib
+	x11-libs/libXft
+	x11-libs/libXrender
+	beagle? ( || (
+		dev-libs/libbeagle
+		=app-misc/beagle-0.2* ) )
+	tracker? ( >=app-misc/tracker-0.6.4 )
+	xmp? ( >=media-libs/exempi-2 )"
+
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40.1
+	doc? ( >=dev-util/gtk-doc-1.4 )
+	gnome-base/gnome-common
+	dev-util/gtk-doc-am"
+
+PDEPEND="gnome? ( >=x11-themes/gnome-icon-theme-1.1.91 )"
+
+DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-update-mimedb
+		--disable-packagekit
+		$(use_enable beagle)
+		$(use_enable tracker)
+		$(use_enable xmp)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# FIXME: tarball generated with broken gtk-doc, revisit me.
+	if use doc; then
+		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
+			-i gtk-doc.make || die "sed 1 failed"
+	else
+		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/bin/true" \
+			-i gtk-doc.make || die "sed 2 failed"
+	fi
+
+	# gtk-doc-am and gnome-common needed for this
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"
+
+	# Fix nautilus flipping-out with --no-desktop -- bug 266398
+	epatch "${FILESDIR}/${PN}-2.26.2-change-reg-desktop-file-with-no-desktop.patch"
+}
+
+src_test() {
+	addwrite "/root/.gnome2_private"
+	unset SESSION_MANAGER
+	Xemake check || die "Test phase failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "nautilus can use gstreamer to preview audio files. Just make sure"
+	elog "to have the necessary plugins available to play the media type you"
+	elog "want to preview"
+}