Bump to 3.2.2 + latest upstream patches. Notable changes: systemMonitor and alternate-tab bugfixes, azerty keyboard compatibility, fixes for alternative-status-menu crashes (should fix bug #392279 reported by jlec). Note that extension IDs in this version have changed; as a result, extensions may have become auto-disabled, and you will need to re-enable them.

(Portage version: 2.2.0_alpha80/cvs/Linux x86_64)

3 files changed, 98 insertions, 3 deletions

diff --git a/gnome-extra/gnome-shell-extensions/ChangeLog b/gnome-extra/gnome-shell-extensions/ChangeLog
index 655392e4dceb..473043aeeba0 100644
--- a/gnome-extra/gnome-shell-extensions/ChangeLog
+++ b/gnome-extra/gnome-shell-extensions/ChangeLog
@@ -1,6 +1,16 @@
 # ChangeLog for gnome-extra/gnome-shell-extensions
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog,v 1.1 2011/11/06 01:42:59 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/ChangeLog,v 1.2 2011/12/11 23:47:05 tetromino Exp $
+
+*gnome-shell-extensions-3.2.2 (11 Dec 2011)
+
+  11 Dec 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  gnome-shell-extensions-3.2.0-r2.ebuild, +gnome-shell-extensions-3.2.2.ebuild:
+  Bump to 3.2.2 + latest upstream patches. Notable changes: systemMonitor and
+  alternate-tab bugfixes, azerty keyboard compatibility, fixes for
+  alternative-status-menu crashes (should fix bug #392279 reported by jlec).
+  Note that extension IDs in this version have changed; as a result, extensions
+  may have become auto-disabled, and you will need to re-enable them.
 
 *gnome-shell-extensions-3.2.0-r2 (06 Nov 2011)
 
diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild
index ae3848c51786..f9748b859ee0 100644
--- a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild
+++ b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild
@@ -1,12 +1,12 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild,v 1.1 2011/11/06 01:42:59 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.0-r2.ebuild,v 1.2 2011/12/11 23:47:05 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
 GNOME2_LA_PUNT="yes"
 
-inherit gnome2
+inherit eutils gnome2
 
 DESCRIPTION="JavaScript extensions for GNOME Shell"
 HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"
diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.2.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.2.ebuild
new file mode 100644
index 000000000000..e0ad00edc5f3
--- /dev/null
+++ b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.2.2.ebuild,v 1.1 2011/12/11 23:47:05 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="JavaScript extensions for GNOME Shell"
+HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"
+# Tarball not available from upstream website
+SRC_URI="http://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}.tar.xz
+	http://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}-patches-1.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.26
+	>=gnome-base/gnome-desktop-2.91.6:3[introspection]
+	>=gnome-base/libgtop-2.28.3[introspection]
+	>=app-admin/eselect-gnome-shell-extensions-20111211"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-libs/gjs-1.29
+	dev-libs/gobject-introspection
+	>=gnome-base/gnome-shell-3.2
+	media-libs/clutter:1.0[introspection]
+	net-libs/telepathy-glib[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/pango[introspection]"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.22
+	>=dev-util/intltool-0.26
+	gnome-base/gnome-common"
+
+pkg_setup() {
+	DOCS="NEWS README"
+	G2CONF="${G2CONF}
+		--enable-extensions=all
+		--disable-schemas-compile"
+}
+
+src_prepare() {
+	# Useful/necessary patches from upstream, will be in the next release
+	epatch ../patch/*.patch
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+
+	local example="example@gnome-shell-extensions.gcampax.github.com"
+	if use examples; then
+		mv "${ED}usr/share/gnome-shell/extensions/${example}" \
+			"${ED}usr/share/doc/${PF}/" || die
+	else
+		rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
+	fi
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	elog
+	elog "Installed extensions installed are initially disabled by default."
+	elog "To change the system default and enable some extensions, you can use"
+	elog "# eselect gnome-shell-extensions"
+	elog "Alternatively, to enable/disable extensions on a per-user basis,"
+	elog "you can use the https://extensions.gnome.org/ web interface, the"
+	elog "gnome-extra/gnome-tweak-tool GUI, or modify the org.gnome.shell"
+	elog "enabled-extensions gsettings key from the command line or a script."
+	elog
+	elog "In ${PN}-3.2.2, extension IDs have changed from"
+	elog "*.gnome.org to *.gcampax.github.com. As a result, extensions may"
+	elog "have become disabled, and you will need to re-enable them."
+}