Bump to KDE 3.5.8.

(Portage version: 2.1.3.15)

3 files changed, 101 insertions, 1 deletions

diff --git a/kde-base/arts/ChangeLog b/kde-base/arts/ChangeLog
index 0bd470e8e69f..15e7af0f6207 100644
--- a/kde-base/arts/ChangeLog
+++ b/kde-base/arts/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/arts
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.252 2007/05/22 20:19:45 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.253 2007/10/19 21:46:46 philantrop Exp $
+
+*arts-3.5.8 (19 Oct 2007)
+
+  19 Oct 2007; Wulf C. Krueger <philantrop@gentoo.org> +arts-3.5.8.ebuild:
+  Bump to KDE 3.5.8.
 
   22 May 2007; Carsten Lohrke <carlo@gentoo.org>
   +files/arts-1.5.5-gcc4.3-build-fix.diff, arts-3.5.5.ebuild:
diff --git a/kde-base/arts/arts-3.5.8.ebuild b/kde-base/arts/arts-3.5.8.ebuild
new file mode 100644
index 000000000000..d4e01371cec9
--- /dev/null
+++ b/kde-base/arts/arts-3.5.8.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/arts-3.5.8.ebuild,v 1.1 2007/10/19 21:46:46 philantrop Exp $
+
+inherit kde flag-o-matic eutils versionator
+set-kdedir 3.5
+
+MY_PV="1.$(get_version_component_range 2-3)"
+S=${WORKDIR}/${PN}-${MY_PV}
+
+RESTRICT="test"
+
+DESCRIPTION="aRts, the KDE sound (and all-around multimedia) server/output manager"
+HOMEPAGE="http://multimedia.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${PN}-${MY_PV}.tar.bz2"
+LICENSE="GPL-2 LGPL-2"
+
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa esd artswrappersuid jack mp3 nas vorbis"
+
+RDEPEND="$(qt_min_version 3.3)
+	>=dev-libs/glib-2
+	alsa? ( media-libs/alsa-lib )
+	vorbis? ( media-libs/libogg
+			media-libs/libvorbis )
+	esd? ( media-sound/esound )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.90 )
+	mp3? ( media-libs/libmad )
+	nas? ( media-libs/nas )
+	media-libs/audiofile"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+PATCHES="${FILESDIR}/arts-1.5.0-bindnow.patch
+	${FILESDIR}/arts-1.5.4-multilib.patch"
+
+src_unpack() {
+	kde_src_unpack
+
+	sed -i -e "s:GENTOO_LIB64:$(get_abi_LIBDIR amd64):" \
+		-e "s:GENTOO_LIB32:$(get_abi_LIBDIR x86):" artsc/artsdsp.in \
+		|| die "multilib-sed failed"
+
+	# Alternative to arts-1.4-mcopidl.patch, make sure that flags are supported
+	# before trying to use them, for non-GCC, vanilla GCC or GCC 4.1 compilers
+	local nosspflags
+
+	nosspflags="$(test-flags -fno-stack-protector -fno-stack-protector-all)"
+	sed -i -e "s:KDE_CXXFLAGS =\(.*\):KDE_CXXFLAGS = \1 ${nosspflags}:" \
+		"${S}/mcopidl/Makefile.am"
+
+	# Fix libao/gaim problems with aRTs. See bug #116290.
+	epatch "${FILESDIR}/arts-1.5.0-check_tmp_dir.patch"
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	myconf="$(use_enable alsa) $(use_enable vorbis)
+			$(use_enable mp3 libmad) $(use_with jack)
+			$(use_with esd) $(use_with nas)
+		--with-audiofile --without-mas"
+
+	#fix bug 13453
+	filter-flags -foptimize-sibling-calls
+
+	# breaks otherwise <gustavoz>
+	use sparc && export CFLAGS="-O1" && export CXXFLAGS="-O1"
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# used for realtime priority, but off by default as it is a security hazard
+	use artswrappersuid && chmod u+s "${D}/${PREFIX}/bin/artswrapper"
+}
+
+pkg_postinst() {
+	if ! use artswrappersuid ; then
+		elog "Run chmod u+s ${PREFIX}/bin/artswrapper to let artsd use realtime priority"
+		elog "and so avoid possible skips in sound. However, on untrusted systems this"
+		elog "creates the possibility of a DoS attack that'll use 100% cpu at realtime"
+		elog "priority, and so is off by default. See bug #7883."
+		elog "Or, you can set the local artswrappersuid USE flag to make the ebuild do this."
+	fi
+}
diff --git a/kde-base/arts/files/digest-arts-3.5.8 b/kde-base/arts/files/digest-arts-3.5.8
new file mode 100644
index 000000000000..0bb3ecf9f96a
--- /dev/null
+++ b/kde-base/arts/files/digest-arts-3.5.8
@@ -0,0 +1,3 @@
+MD5 061ce49351d970a81f4c0a1b0339fb34 arts-1.5.8.tar.bz2 970899
+RMD160 0c8e92bed7ff8c85e324ba88d2b421a1009e5669 arts-1.5.8.tar.bz2 970899
+SHA256 ec2f4541740bb7b4bfa4a0ae1d9d1e2b0f6fcb31953b317497129dfc122c4f96 arts-1.5.8.tar.bz2 970899