Version bump.

(Portage version: 2.1.2.7)

3 files changed, 72 insertions, 1 deletions

diff --git a/kde-base/kdegraphics/ChangeLog b/kde-base/kdegraphics/ChangeLog
index 221915c3fa63..eb988b2422b9 100644
--- a/kde-base/kdegraphics/ChangeLog
+++ b/kde-base/kdegraphics/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdegraphics
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/ChangeLog,v 1.303 2007/05/15 21:27:17 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/ChangeLog,v 1.304 2007/05/22 22:47:17 carlo Exp $
+
+*kdegraphics-3.5.7 (22 May 2007)
+
+  22 May 2007; Carsten Lohrke <carlo@gentoo.org> +kdegraphics-3.5.7.ebuild:
+  Version bump.
 
 *kdegraphics-3.5.6-r2 (15 May 2007)
 
diff --git a/kde-base/kdegraphics/files/digest-kdegraphics-3.5.7 b/kde-base/kdegraphics/files/digest-kdegraphics-3.5.7
new file mode 100644
index 000000000000..ba24610e2ca5
--- /dev/null
+++ b/kde-base/kdegraphics/files/digest-kdegraphics-3.5.7
@@ -0,0 +1,3 @@
+MD5 eae753e80c5f8dd304e7fd0dca84ae67 kdegraphics-3.5.7.tar.bz2 7424976
+RMD160 ccf36f5c34a1d484f0878a42a51dc620c2bdfa71 kdegraphics-3.5.7.tar.bz2 7424976
+SHA256 5689882ade29d0f56e95783f1c3e443fd512ca8291bcb81aac60ac719a8dcdcc kdegraphics-3.5.7.tar.bz2 7424976
diff --git a/kde-base/kdegraphics/kdegraphics-3.5.7.ebuild b/kde-base/kdegraphics/kdegraphics-3.5.7.ebuild
new file mode 100644
index 000000000000..3568d8119924
--- /dev/null
+++ b/kde-base/kdegraphics/kdegraphics-3.5.7.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/kdegraphics-3.5.7.ebuild,v 1.1 2007/05/22 22:47:17 carlo Exp $
+
+inherit kde-dist eutils
+
+DESCRIPTION="KDE graphics-related apps"
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gphoto2 imlib openexr opengl pdf povray scanner tetex"
+
+DEPEND="~kde-base/kdebase-${PV}
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	gphoto2? ( media-libs/libgphoto2 )
+	scanner? ( media-gfx/sane-backends )
+	media-libs/libart_lgpl
+	media-libs/lcms
+	dev-libs/fribidi
+	imlib? ( media-libs/imlib )
+	virtual/ghostscript
+	media-libs/tiff
+	openexr? ( >=media-libs/openexr-1.2 )
+	povray? ( media-gfx/povray
+		  virtual/opengl )
+	pdf? ( >=app-text/poppler-0.5.1
+		>=app-text/poppler-bindings-0.5.1 )"
+
+RDEPEND="${DEPEND}
+	tetex? (
+	|| ( >=app-text/tetex-2
+		 app-text/ptex
+		 app-text/cstetex
+		 app-text/dvipdfm ) )"
+
+pkg_setup() {
+	kde_pkg_setup
+	for ghostscript in app-text/ghostscript-{gnu,esp,afpl}; do
+		if has_version ${ghostscript} && ! built_with_use ${ghostscript} X; then
+			eerror "This package requires ${ghostscript} compiled with X11 support."
+			eerror "Please reemerge ${ghostscript} with USE=\"X\"."
+			die "Please reemerge ${ghostscript} with USE=\"X\"."
+		fi
+	done
+	if use pdf && ! built_with_use app-text/poppler-bindings qt3; then
+		eerror "This package requires app-text/poppler-bindings compiled with Qt 3.x support."
+		eerror "Please reemerge app-text/poppler-bindings with USE=\"qt3\"."
+		die "Please reemerge app-text/poppler-bindings with USE=\"qt3\"."
+	fi
+}
+
+src_compile() {
+	local myconf="$(use_with openexr) $(use_with pdf poppler)
+				  $(use_with gphoto2 kamera)"
+
+	use imlib || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kuickshow"
+	use scanner || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kooka libkscan"
+	use povray || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kpovmodeler"
+	use pdf || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kpdf"
+
+	rm -f "${S}/configure" # ask rebuilding
+	kde_src_compile
+}