fix ntlm authentication, #98285 and konqueror crashes

(Portage version: 2.0.51.22-r1)

1 files changed, 122 insertions, 0 deletions

diff --git a/kde-base/kdelibs/kdelibs-3.4.1-r2.ebuild b/kde-base/kdelibs/kdelibs-3.4.1-r2.ebuild
new file mode 100644
index 000000000000..af1bdfc47fee
--- /dev/null
+++ b/kde-base/kdelibs/kdelibs-3.4.1-r2.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-3.4.1-r2.ebuild,v 1.1 2005/07/10 20:16:35 carlo Exp $
+
+inherit kde flag-o-matic eutils multilib
+set-qtdir 3
+set-kdedir 3.4
+
+DESCRIPTION="KDE libraries needed by all kde programs"
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="3.4"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa arts cups doc jpeg2k kerberos openexr spell ssl tiff zeroconf"
+
+# kde.eclass has kdelibs in DEPEND, and we can't have that in here.
+# so we recreate the entire DEPEND from scratch.
+RDEPEND="arts? ( ~kde-base/arts-${PV} )
+	>=x11-libs/qt-3.3.3
+	app-arch/bzip2
+	>=dev-libs/libxslt-1.1.4
+	>=dev-libs/libxml2-2.6.6
+	>=dev-libs/libpcre-4.2
+	media-libs/libart_lgpl
+	net-dns/libidn
+	virtual/utempter
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( >=net-print/cups-1.1.19 )
+	tiff? ( media-libs/tiff )
+	kerberos? ( virtual/krb5 )
+	jpeg2k? ( media-libs/jasper )
+	openexr? ( >=media-libs/openexr-1.2 )
+	spell? ( || ( app-text/aspell
+	              app-text/ispell ) )
+	zeroconf? ( net-misc/mDNSResponder )
+	virtual/fam
+	virtual/ghostscript"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/autoconf-2.58
+	>=sys-devel/automake-1.8
+	doc? ( app-doc/doxygen )
+	sys-devel/gettext
+	dev-util/pkgconfig"
+
+src_unpack() {
+	kde_src_unpack
+
+	epatch "${FILESDIR}/${P}-configure.patch"
+	# fix ntlm authentication
+	epatch "${FILESDIR}/${P}-kntlm.patch"
+	# fix some annoying konqueror crashes
+	epatch "${FILESDIR}/${P}-ktoolbar-crash.patch"
+	# for the configure patch
+	make -f admin/Makefile.common || die
+}
+
+src_compile() {
+	myconf="--with-distribution=Gentoo
+	        --enable-libfam $(use_enable kernel_linux dnotify)
+	        --with-libart --with-libidn --with-utempter
+	        $(use_with alsa) $(use_with arts) $(use_with ssl)
+	        $(use_with kerberos gssapi) $(use_with tiff)
+	        $(use_with jpeg2k jasper) $(use_with openexr)
+	        $(use_enable cups) $(use_enable zeroconf dnssd)"
+
+	if use spell && has_version app-text/aspell; then
+		myconf="${myconf} --with-aspell"
+	else
+		myconf="${myconf} --without-aspell"
+	fi
+
+	use x86 && myconf="${myconf} --enable-fast-malloc=full"
+
+	# fix bug 58179, bug 85593
+	# kdelibs-3.4.0 needed -fno-gcse; 3.4.1 needs -mminimal-toc; this needs a
+	# closer look... - corsair
+	use ppc64 && append-flags "-mminimal-toc"
+
+	kde_src_compile
+
+	if use doc; then
+		make apidox || die
+	fi
+}
+
+src_install() {
+	kde_src_install
+
+	if use doc; then
+		make DESTDIR="${D}" install-apidox || die
+	fi
+
+	# needed to fix lib64 issues on amd64, see bug #45669
+	use amd64 && ln -s ${KDEDIR}/lib ${D}/${KDEDIR}/lib64
+
+	# Needed to create lib -> lib64 symlink for amd64 2005.0 profile
+	if [ "${SYMLINK_LIB}" = "yes" ]; then
+		dosym $(get_abi_LIBDIR ${DEFAULT_ABI}) ${KDEDIR}/lib
+	fi
+
+	if ! use arts ; then
+		dodir /etc/env.d
+
+		# List all the multilib libdirs
+		local libdirs
+		for libdir in $(get_all_libdirs); do
+			libdirs="${libdirs}:${PREFIX}/${libdir}"
+		done
+
+		cat <<EOF > ${D}/etc/env.d/46kdepaths-${SLOT} # number goes down with version upgrade
+PATH=${PREFIX}/bin
+ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
+LDPATH=${libdirs:1}
+CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown"
+EOF
+	fi
+
+}