Version bump KDE SC 4.9.2

(Portage version: 2.2.0_alpha134/cvs/Linux x86_64)

2 files changed, 77 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index 46f4c1f00d84..5c96b6f6da07 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.162 2012/09/21 09:33:06 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.163 2012/10/02 18:11:40 johu Exp $
+
+*kdepimlibs-4.9.2 (02 Oct 2012)
+
+  02 Oct 2012; Johannes Huber <johu@gentoo.org> +kdepimlibs-4.9.2.ebuild:
+  Version bump KDE SC 4.9.2
 
   21 Sep 2012; Johannes Huber <johu@gentoo.org> -kdepimlibs-4.9.0.ebuild:
   Remove KDE SC 4.9.0
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.9.2.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.9.2.ebuild
new file mode 100644
index 000000000000..757e4465a6db
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.9.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.9.2.ebuild,v 1.1 2012/10/02 18:11:40 johu Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap prison semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	>=dev-libs/boost-1.35.0-r5
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	prison? ( media-libs/prison )
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.8.0
+		media-libs/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+# boost is not linked to, but headers which include it are installed
+# bug #418071
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-4.9.1-boostincludes.patch" )
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use !semantic-desktop KALARM_USE_KRESOURCES)
+		$(cmake-utils_use_with prison)
+	)
+
+	kde4-base_src_configure
+}