Add KDE 4.2.2

(Portage version: 2.2_rc29/cvs/Linux x86_64)

2 files changed, 94 insertions, 1 deletions

diff --git a/kde-base/systemsettings/ChangeLog b/kde-base/systemsettings/ChangeLog
index 5368f5e77b2b..fb04fceb6c65 100644
--- a/kde-base/systemsettings/ChangeLog
+++ b/kde-base/systemsettings/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.26 2009/04/11 19:51:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.27 2009/04/12 06:47:48 alexxy Exp $
+
+*systemsettings-4.2.2 (11 Apr 2009)
+
+  11 Apr 2009; Alexey Shvetsov <alexxy@gentoo.org>
+  +systemsettings-4.2.2.ebuild:
+  Add KDE 4.2.2
 
   11 Apr 2009; Raúl Porcel <armin76@gentoo.org>
   systemsettings-4.2.1-r1.ebuild:
diff --git a/kde-base/systemsettings/systemsettings-4.2.2.ebuild b/kde-base/systemsettings/systemsettings-4.2.2.ebuild
new file mode 100644
index 000000000000..237020b8fb42
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-4.2.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.2.2.ebuild,v 1.1 2009/04/12 06:47:48 alexxy Exp $
+
+EAPI="2"
+
+KMNAME="kdebase-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="System settings utility"
+IUSE="debug doc +usb xinerama"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+
+COMMONDEPEND="
+	>=dev-libs/glib-2
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=x11-libs/libxklavier-3.2
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	opengl? ( virtual/opengl )
+	usb? ( dev-libs/libusb )
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/kbproto
+	x11-proto/xextproto
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}
+	>=kde-base/kcontrol-${PV}:${SLOT}[kdeprefix=]
+	x11-apps/setxkbmap
+	|| (
+		x11-misc/xkbdata
+		x11-misc/xkeyboard-config
+	)
+"
+
+KMEXTRA="
+	kcontrol/
+"
+KMEXTRACTONLY="
+	krunner/dbus/org.kde.krunner.App.xml
+	krunner/dbus/org.kde.screensaver.xml
+	kwin/
+	libs/
+	plasma/
+"
+
+PATCHES=( "$FILESDIR/20_use_dejavu_as_default_font.patch" )
+
+src_unpack() {
+	if use doc; then
+		KMEXTRA="${KMEXTRA}
+			doc/kcontrol
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_prepare() {
+	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
+		systemsettings/CMakeLists.txt \
+		|| die "Failed to fix systemsettingsrc install location"
+
+	kde4-meta_src_prepare
+}
+
+# FIXME: is have_openglxvisual found without screensaver
+src_configure() {
+	# Old keyboard-detection code is unmaintained,
+	# so we force the new stuff, using libxklavier.
+	mycmakeargs="${mycmakeargs}
+		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
+		-DWITH_GLIB2=ON -DWITH_GObject=ON
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with usb USB)
+		$(cmake-utils_use_with xinerama X11_Xinerama)"
+
+	kde4-meta_src_configure
+}