bump to 2.20.0 and fix QA warnings

(Portage version: 2.1.3.12)

7 files changed, 187 insertions, 10 deletions

diff --git a/mail-client/evolution/ChangeLog b/mail-client/evolution/ChangeLog
index 46d45af99939..c78d1892075b 100644
--- a/mail-client/evolution/ChangeLog
+++ b/mail-client/evolution/ChangeLog
@@ -1,6 +1,19 @@
 # ChangeLog for mail-client/evolution
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.202 2007/09/27 11:56:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.203 2007/10/12 14:40:18 eva Exp $
+
+  12 Oct 2007; Gilles Dartiguelongue <eva@gentoo.org>
+  evolution-2.8.3-r2.ebuild, evolution-2.10.2.ebuild,
+  evolution-2.10.3.ebuild:
+  fix QA warnings
+
+*evolution-2.12.0 (12 Oct 2007)
+
+  12 Oct 2007; Gilles Dartiguelongue <eva@gentoo.org>
+  +files/evolution-2.11.90-mail-remote-broken.patch,
+  +evolution-2.12.0.ebuild:
+  bump to 2.12.0, bogofilter & spamassasin are pure runtime dependency so
+  removed them
 
   27 Sep 2007; Raúl Porcel <armin76@gentoo.org> evolution-2.10.3.ebuild:
   alpha/ia64 stable wrt #193339
diff --git a/mail-client/evolution/evolution-2.10.2.ebuild b/mail-client/evolution/evolution-2.10.2.ebuild
index 0fb8b44c34a7..55fe586dc191 100644
--- a/mail-client/evolution/evolution-2.10.2.ebuild
+++ b/mail-client/evolution/evolution-2.10.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.10.2.ebuild,v 1.11 2007/08/28 18:18:08 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.10.2.ebuild,v 1.12 2007/10/12 14:40:18 eva Exp $
 
 WANT_AUTOCONF="latest"
 WANT_AUTOMAKE="1.9"
@@ -164,7 +164,7 @@ src_unpack() {
 	use bogofilter && epatch "${FILESDIR}"/${PN}-2.9.2-bf-junk.patch.gz
 
 	# certificate filtering for clueless users (and even for those who know)
-	epatch ${FILESDIR}/${PN}-2.8.2.1-certificate-manager-filtering.patch
+	epatch "${FILESDIR}"/${PN}-2.8.2.1-certificate-manager-filtering.patch
 
 	# Fix timezone offsets on fbsd.  bug #183708
 	epatch "${FILESDIR}"/${P}-fbsd.patch
@@ -176,7 +176,7 @@ src_compile() {
 	# Use NSS/NSPR only if 'ssl' is enabled.
 	if use ssl ; then
 		sed -i -e "s|mozilla-nss|nss|
-			s|mozilla-nspr|nspr|" ${S}/configure
+			s|mozilla-nspr|nspr|" "${S}"/configure
 		G2CONF="${G2CONF} --enable-nss=yes"
 	else
 		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
diff --git a/mail-client/evolution/evolution-2.10.3.ebuild b/mail-client/evolution/evolution-2.10.3.ebuild
index cbd6c07b83c2..68f7ad76800a 100644
--- a/mail-client/evolution/evolution-2.10.3.ebuild
+++ b/mail-client/evolution/evolution-2.10.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.10.3.ebuild,v 1.7 2007/09/27 11:56:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.10.3.ebuild,v 1.8 2007/10/12 14:40:18 eva Exp $
 
 WANT_AUTOCONF="latest"
 WANT_AUTOMAKE="1.9"
@@ -164,14 +164,14 @@ src_unpack() {
 	use bogofilter && epatch "${FILESDIR}"/${PN}-2.9.2-bf-junk.patch.gz
 
 	# certificate filtering for clueless users (and even for those who know)
-	epatch ${FILESDIR}/${PN}-2.8.2.1-certificate-manager-filtering.patch
+	epatch "${FILESDIR}"/${PN}-2.8.2.1-certificate-manager-filtering.patch
 
 	# Fix timezone offsets on fbsd.  bug #183708
 	epatch "${FILESDIR}"/${PN}-2.10.2-fbsd.patch
 
 	# Maildir account configured to select files and not directories bug 133504
 	# Requires DEPEND on >=e-d-s-1.10.2-r1.
-	epatch ${FILESDIR}/${PN}-2.10-fix-maildir-account.patch
+	epatch "${FILESDIR}"/${PN}-2.10-fix-maildir-account.patch
 
 	eautoreconf
 }
@@ -180,7 +180,7 @@ src_compile() {
 	# Use NSS/NSPR only if 'ssl' is enabled.
 	if use ssl ; then
 		sed -i -e "s|mozilla-nss|nss|
-			s|mozilla-nspr|nspr|" ${S}/configure
+			s|mozilla-nspr|nspr|" "${S}"/configure
 		G2CONF="${G2CONF} --enable-nss=yes"
 	else
 		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
diff --git a/mail-client/evolution/evolution-2.12.0.ebuild b/mail-client/evolution/evolution-2.12.0.ebuild
new file mode 100644
index 000000000000..8889387a7b59
--- /dev/null
+++ b/mail-client/evolution/evolution-2.12.0.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.12.0.ebuild,v 1.1 2007/10/12 14:40:18 eva Exp $
+
+inherit gnome2 flag-o-matic
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="http://www.gnome.org/projects/evolution/"
+SRC_URI="${SRC_URI}"
+
+LICENSE="GPL-2 FDL-1.1"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+# gstreamer for audio-inline, when it uses 0.10
+IUSE="crypt dbus debug doc hal ipv6 kerberos krb4 ldap mono networkmanager nntp pda profile spell ssl"
+
+# Pango dependency required to avoid font rendering problems
+RDEPEND="
+	>=x11-libs/gtk+-2.10
+	>=gnome-extra/evolution-data-server-1.11.90
+	>=x11-themes/gnome-icon-theme-1.2
+	>=gnome-base/gnome-vfs-2.4
+	>=gnome-base/libbonoboui-2.4.2
+	>=gnome-base/libbonobo-2.4.2
+	>=gnome-extra/gtkhtml-3.16
+	>=gnome-base/gconf-2
+	>=gnome-base/libglade-2
+	>=gnome-base/libgnomecanvas-2
+	>=gnome-base/libgnomeui-2
+	>=dev-libs/libxml2-2
+	dbus? ( dev-libs/dbus-glib )
+	hal? ( >=sys-apps/hal-0.5.4 )
+	x11-libs/libnotify
+	pda? (
+		>=app-pda/gnome-pilot-2.0.15
+		>=app-pda/gnome-pilot-conduits-2 )
+	dev-libs/atk
+	ssl? (
+		>=dev-libs/nspr-4.6.1
+		>=dev-libs/nss-3.11 )
+	networkmanager? ( net-misc/networkmanager )
+	>=net-libs/libsoup-2.2.96
+	kerberos? ( virtual/krb5 )
+	krb4? ( virtual/krb5 )
+	>=dev-libs/glib-2.10
+	>=gnome-base/orbit-2.9.8
+	spell? ( >=app-text/gnome-spell-1.0.5 )
+	crypt? ( || ( >=app-crypt/gnupg-2.0.1-r2 =app-crypt/gnupg-1.4* ) )
+	ldap? ( >=net-nds/openldap-2 )
+	mono? ( >=dev-lang/mono-1 )"
+#	gstreamer? (
+#		>=media-libs/gstreamer-0.10
+#		>=media-libs/gst-plugins-base-0.10 )
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.35.5
+	sys-devel/gettext
+	sys-devel/bison
+	app-text/scrollkeeper
+	>=gnome-base/gnome-common-2.12.0
+	>=app-text/gnome-doc-utils-0.9.1
+	doc? ( >=dev-util/gtk-doc-0.6 )"
+
+DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
+ELTCONF="--reverse-deps"
+
+
+pkg_setup() {
+	G2CONF="--without-kde-applnk-path        \
+		--enable-plugins=experimental    \
+		$(use_enable ssl nss)            \
+		$(use_enable ssl smime)          \
+		$(use_enable ipv6)               \
+		$(use_enable mono)               \
+		$(use_enable nntp)               \
+		$(use_enable pda pilot-conduits) \
+		$(use_enable profile profiling)  \
+		$(use_with ldap openldap)        \
+		$(use_with kerberos krb5 /usr)"
+
+	# We need a graphical pinentry frontend to be able to ask for the GPG
+	# password from inside evolution, bug 160302
+	if use crypt && has_version '>=app-crypt/gnupg-2.0.1-r2'; then
+		if ! built_with_use -o app-crypt/pinentry gtk qt3; then
+			die "You must build app-crypt/pinentry with GTK or QT3 support"
+		fi
+	fi
+
+	if use krb4 && ! built_with_use virtual/krb5 krb4; then
+		ewarn
+		ewarn "In order to add kerberos 4 support, you have to emerge"
+		ewarn "virtual/krb5 with the 'krb4' USE flag enabled as well."
+		ewarn
+		ewarn "Skipping for now."
+		ewarn
+		G2CONF="${G2CONF} --without-krb4"
+	else
+		G2CONF="${G2CONF} $(use_with krb4 krb4 /usr)"
+	fi
+
+	# dang - I've changed this to do --enable-plugins=experimental.  This will autodetect
+	# new-mail-notify and exchange, but that cannot be helped for the moment.
+	# They should be changed to depend on a --enable-<foo> like mono is.  This
+	# cleans up a ton of crap from this ebuild.
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Mail-remote doesn't build
+	epatch "${FILESDIR}"/${PN}-2.11.90-mail-remote-broken.patch
+}
+
+src_compile() {
+	# Use NSS/NSPR only if 'ssl' is enabled.
+	if use ssl ; then
+		sed -i -e "s|mozilla-nss|nss|
+			s|mozilla-nspr|nspr|" "${S}"/configure
+		G2CONF="${G2CONF} --enable-nss=yes"
+	else
+		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
+			--without-nss-libs --without-nss-includes"
+	fi
+
+	# problems with -O3 on gcc-3.3.1
+	replace-flags -O3 -O2
+
+	if [ "${ARCH}" = "hppa" ]; then
+		append-flags "-fPIC -ffunction-sections"
+		export LDFLAGS="-ffunction-sections -Wl,--stub-group-size=25000"
+	fi
+
+	gnome2_src_compile
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "To change the default browser if you are not using GNOME, do:"
+	elog "gconftool-2 --set /desktop/gnome/url-handlers/http/command -t string 'mozilla %s'"
+	elog "gconftool-2 --set /desktop/gnome/url-handlers/https/command -t string 'mozilla %s'"
+	elog ""
+	elog "Replace 'mozilla %s' with which ever browser you use."
+	elog ""
+	elog "Junk filters are now a run-time choice. You will get a choice of"
+	elog "bogofilter or spamassassin based on which you have installed"
+	elog ""
+	elog "You have to install one of these for the spam filtering to actually work"
+}
diff --git a/mail-client/evolution/evolution-2.8.3-r2.ebuild b/mail-client/evolution/evolution-2.8.3-r2.ebuild
index 0031f6c467a5..72e5498f34b1 100644
--- a/mail-client/evolution/evolution-2.8.3-r2.ebuild
+++ b/mail-client/evolution/evolution-2.8.3-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.8.3-r2.ebuild,v 1.9 2007/07/08 05:00:26 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.8.3-r2.ebuild,v 1.10 2007/10/12 14:40:18 eva Exp $
 
 inherit eutils flag-o-matic alternatives gnome2 autotools
 
@@ -187,7 +187,7 @@ src_compile() {
 	# Use NSS/NSPR only if 'ssl' is enabled.
 	if use ssl ; then
 		sed -i -e "s|mozilla-nss|nss|
-			s|mozilla-nspr|nspr|" ${S}/configure
+			s|mozilla-nspr|nspr|" "${S}"/configure
 		G2CONF="${G2CONF} --enable-nss=yes"
 	else
 		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
diff --git a/mail-client/evolution/files/digest-evolution-2.12.0 b/mail-client/evolution/files/digest-evolution-2.12.0
new file mode 100644
index 000000000000..6f4ea3948ee5
--- /dev/null
+++ b/mail-client/evolution/files/digest-evolution-2.12.0
@@ -0,0 +1,3 @@
+MD5 aaa378a63477b56de214ea9eaa7f8560 evolution-2.12.0.tar.bz2 25562079
+RMD160 238c92d0fef5478bc6a51312ab8c68b970e9db98 evolution-2.12.0.tar.bz2 25562079
+SHA256 f1b9fc4f02d297c797bf3953f0742f745efc2c0ebb893d126c0e3a9bac84fe56 evolution-2.12.0.tar.bz2 25562079
diff --git a/mail-client/evolution/files/evolution-2.11.90-mail-remote-broken.patch b/mail-client/evolution/files/evolution-2.11.90-mail-remote-broken.patch
new file mode 100644
index 000000000000..2549e0ebd1fa
--- /dev/null
+++ b/mail-client/evolution/files/evolution-2.11.90-mail-remote-broken.patch
@@ -0,0 +1,11 @@
+--- configure.old	2007-08-14 20:39:02.320171822 +0200
++++ configure	2007-08-14 20:38:06.813953026 +0200
+@@ -35748,7 +35748,7 @@
+ plugins_standard="$plugins_standard_always"
+ all_plugins_standard="$plugins_standard"
+ 
+-plugins_experimental_always="backup-restore folder-unsubscribe mail-to-meeting mail-remote save-attachments"
++plugins_experimental_always="backup-restore folder-unsubscribe mail-to-meeting save-attachments"
+ plugins_experimental="$plugins_experimental_always $IPOD_SYNC $TNEF_ATTACHMENTS"
+ all_plugins_experimental="$plugins_experimental_always ipod-sync tnef-attachments"
+