Add desktop menu entry, bug #233824, thank Simon Zilliken for work.

(Portage version: 2.2_rc8/cvs/Linux 2.6.25-gentoo-r7 x86_64)

2 files changed, 85 insertions, 1 deletions

diff --git a/media-gfx/xfig/ChangeLog b/media-gfx/xfig/ChangeLog
index dffb5d9eeb6d..4087e67dd877 100644
--- a/media-gfx/xfig/ChangeLog
+++ b/media-gfx/xfig/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/xfig
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/xfig/ChangeLog,v 1.51 2008/05/11 12:09:54 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/xfig/ChangeLog,v 1.52 2008/08/13 14:37:19 pva Exp $
+
+*xfig-3.2.5-r3 (13 Aug 2008)
+
+  13 Aug 2008; Peter Volkov <pva@gentoo.org> +xfig-3.2.5-r3.ebuild:
+  Add desktop menu entry, bug #233824, thank Simon Zilliken for work.
 
 *xfig-3.2.5-r2 (11 May 2008)
 
diff --git a/media-gfx/xfig/xfig-3.2.5-r3.ebuild b/media-gfx/xfig/xfig-3.2.5-r3.ebuild
new file mode 100644
index 000000000000..1522d27e3865
--- /dev/null
+++ b/media-gfx/xfig/xfig-3.2.5-r3.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/xfig/xfig-3.2.5-r3.ebuild,v 1.1 2008/08/13 14:37:19 pva Exp $
+
+inherit eutils multilib
+
+MY_P=${PN}.${PV}
+DESCRIPTION="A menu-driven tool to draw and manipulate objects interactively in an X window."
+HOMEPAGE="http://www.xfig.org"
+SRC_URI="http://www.xfig.org/software/xfig/3.2.5/${MY_P}.full.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libXaw
+		x11-libs/libXp
+		x11-libs/Xaw3d
+		media-libs/jpeg
+		media-libs/libpng
+		>=media-gfx/transfig-3.2.5-r1
+		media-libs/netpbm"
+DEPEND="${RDEPEND}
+		x11-misc/imake
+		app-text/rman
+		x11-proto/xproto
+		x11-proto/inputproto
+		x11-libs/libXi"
+
+S="${WORKDIR}"/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# We do not have nescape. Let's use firefox instead...
+	sed -i "s+netscape+firefox+g" Fig.ad
+	find "${S}" -type f -exec chmod -x \{\} \;
+}
+
+sed_Imakefile() {
+	# see Imakefile for details
+	vars2subs="BINDIR=/usr/bin
+		PNGINC=-I/usr/include
+		JPEGLIBDIR=/usr/$(get_libdir)
+		JPEGINC=-I/usr/include
+		XPMLIBDIR=/usr/$(get_libdir)
+		XPMINC=-I/usr/include/X11
+		USEINLINE=-DUSE_INLINE
+		XFIGLIBDIR=/usr/share/xfig
+		XFIGDOCDIR=/usr/share/doc/${P}
+		MANDIR=/usr/share/man/man\$\(MANSUFFIX\)
+		CC=$(tc-getCC)"
+
+	for variable in ${vars2subs} ; do
+		varname=${variable%%=*}
+		varval=${variable##*=}
+		sed -i "s:^\(XCOMM\)*[[:space:]]*${varname}[[:space:]]*=.*$:${varname} = ${varval}:" "$@"
+	done
+}
+
+src_compile() {
+	sed_Imakefile Imakefile
+
+	xmkmf || die
+	emake CC="$(tc-getCC)" LOCAL_LDFLAGS="${LDFLAGS}" CDEBUGFLAGS="${CFLAGS}" \
+	USRLIBDIR=/usr/$(get_libdir) || die
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install.all || die
+
+	insinto /usr/share/doc/${P}
+	doins README FIGAPPS CHANGES LATEX.AND.XFIG
+
+	doicon xfig.png
+	make_desktop_entry xfig Xfig xfig
+}