Version bump. Add doc use flag to install user manual, rename gnome use flag to gnome-keyring, use bundled libraw due to upstream modifications.

(Portage version: 2.2.0_alpha145/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 117 insertions, 1 deletions

diff --git a/media-gfx/darktable/ChangeLog b/media-gfx/darktable/ChangeLog
index e1f2ec4b279a..ceea69719b27 100644
--- a/media-gfx/darktable/ChangeLog
+++ b/media-gfx/darktable/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/darktable
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.25 2012/12/09 00:04:51 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.26 2012/12/10 04:30:54 radhermit Exp $
+
+*darktable-1.1.1 (10 Dec 2012)
+
+  10 Dec 2012; Tim Harder <radhermit@gentoo.org> +darktable-1.1.1.ebuild:
+  Version bump. Add doc use flag to install user manual, rename gnome use flag
+  to gnome-keyring, use bundled libraw due to upstream modifications.
 
   09 Dec 2012; Tim Harder <radhermit@gentoo.org> darktable-1.1.ebuild:
   Check for openmp support in pkg_pretend as well (bug #446368) and remove
diff --git a/media-gfx/darktable/darktable-1.1.1.ebuild b/media-gfx/darktable/darktable-1.1.1.ebuild
new file mode 100644
index 000000000000..9bfdb627e01e
--- /dev/null
+++ b/media-gfx/darktable/darktable-1.1.1.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-1.1.1.ebuild,v 1.1 2012/12/10 04:30:54 radhermit Exp $
+
+EAPI="5"
+
+inherit cmake-utils toolchain-funcs gnome2-utils
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="http://www.darktable.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	doc? ( mirror://sourceforge/${PN}/${PN}-usermanual-${PV}.pdf )"
+
+LICENSE="GPL-3 CCPL-Attribution-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colord debug doc facebook flickr geo gnome-keyring gphoto2 kde nls opencl openmp +rawspeed
++slideshow video_cards_nvidia"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/libxml2:2
+	colord? ( x11-misc/colord )
+	facebook? ( dev-libs/json-glib )
+	flickr? ( media-libs/flickcurl )
+	geo? ( net-libs/libsoup:2.4 )
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	gnome-base/librsvg:2
+	gphoto2? ( media-libs/libgphoto2 )
+	kde? (
+		dev-libs/dbus-glib
+		kde-base/kwalletd
+	)
+	media-gfx/exiv2[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3
+	media-libs/libpng
+	media-libs/openexr
+	media-libs/tiff
+	net-misc/curl
+	opencl? ( virtual/opencl )
+	slideshow? (
+		media-libs/libsdl
+		virtual/glu
+		virtual/opengl
+	)
+	virtual/jpeg
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-opencl-kernels.patch
+	"${FILESDIR}"/${PN}-1.1-cflags.patch
+	"${FILESDIR}"/${PN}-1.1-automagic-colord.patch
+)
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	base_src_prepare
+	sed -i -e "s:\(/share/doc/\)darktable:\1${PF}:" \
+		-e "s:LICENSE::" doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	use debug && CMAKE_BUILD_TYPE=Debug
+
+	local mycmakeargs=(
+		$(cmake-utils_use_use colord COLORD)
+		$(cmake-utils_use_use facebook GLIBJSON)
+		$(cmake-utils_use_use flickr FLICKR)
+		$(cmake-utils_use_use geo GEO)
+		$(cmake-utils_use_use gnome-keyring GNOME_KEYRING)
+		$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
+		$(cmake-utils_use_use kde KWALLET)
+		$(cmake-utils_use_use nls NLS)
+		$(cmake-utils_use_use openmp OPENMP)
+		$(cmake-utils_use !rawspeed DONT_USE_RAWSPEED)
+		$(cmake-utils_use_build slideshow SLIDESHOW)
+		-DUSE_OPENCL=$(usex opencl ON OFF)
+		-DINSTALL_IOP_EXPERIMENTAL=ON
+		-DINSTALL_IOP_LEGACY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use doc && dodoc "${WORKDIR}"/${PN}-usermanual-${PV}.pdf
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}