Version bump. Improved byte-reader API; Various optimizations, bug fixes and improvements

(Portage version: 2.2_rc22/cvs/Linux 2.6.31-gentoo-r6 x86_64)

2 files changed, 61 insertions, 1 deletions

diff --git a/media-libs/gstreamer/ChangeLog b/media-libs/gstreamer/ChangeLog
index e47d2086c309..ec068346e5c3 100644
--- a/media-libs/gstreamer/ChangeLog
+++ b/media-libs/gstreamer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.238 2009/11/10 16:04:51 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.239 2009/11/15 23:47:42 leio Exp $
+
+*gstreamer-0.10.25 (15 Nov 2009)
+
+  15 Nov 2009; Mart Raudsepp <leio@gentoo.org> +gstreamer-0.10.25.ebuild:
+  Version bump. Improved byte-reader API; Various optimizations, bug fixes
+  and improvements
 
   10 Nov 2009; Olivier Crête <tester@gentoo.org> gstreamer-0.10.24.ebuild:
   Stable on amd64, bug #290343
diff --git a/media-libs/gstreamer/gstreamer-0.10.25.ebuild b/media-libs/gstreamer/gstreamer-0.10.25.ebuild
new file mode 100644
index 000000000000..89405f45bbc4
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.10.25.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.25.ebuild,v 1.1 2009/11/15 23:47:42 leio Exp $
+
+EAPI=2
+
+inherit eutils multilib versionator
+
+# Create a major/minor combo for our SLOT and executables suffix
+PV_MAJ_MIN=$(get_version_component_range '1-2')
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="nls test"
+
+RDEPEND=">=dev-libs/glib-2.16:2
+	dev-libs/libxml2
+	>=dev-libs/check-0.9.2"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	# Disable static archives, dependency tracking and examples
+	# to speed up build time
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		$(use_enable nls) \
+		--disable-valgrind \
+		--disable-examples \
+		--enable-check \
+		--disable-introspection \
+		$(use_enable test tests) \
+		--with-package-name="GStreamer ebuild for Gentoo" \
+		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE
+
+	# Remove unversioned binaries to allow SLOT installations in future
+	cd "${D}"/usr/bin
+	local gst_bins
+	for gst_bins in $(ls *-${PV_MAJ_MIN}); do
+		rm -f ${gst_bins/-${PV_MAJ_MIN}/}
+	done
+}