version bump, by Arne Babenhauserheide <arne_bab@web.de>, bug #289908

(Portage version: 2.2_rc46/cvs/Linux x86_64)

2 files changed, 74 insertions, 1 deletions

diff --git a/media-libs/libtheora/ChangeLog b/media-libs/libtheora/ChangeLog
index 33d882b4b3cf..6bd3e0770f66 100644
--- a/media-libs/libtheora/ChangeLog
+++ b/media-libs/libtheora/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libtheora
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.97 2009/09/27 08:16:18 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.98 2009/10/27 11:16:37 aballier Exp $
+
+*libtheora-1.1.1 (27 Oct 2009)
+
+  27 Oct 2009; Alexis Ballier <aballier@gentoo.org> +libtheora-1.1.1.ebuild:
+  version bump, by Arne Babenhauserheide <arne_bab@web.de>, bug #289908
 
 *libtheora-1.1.0 (27 Sep 2009)
 
diff --git a/media-libs/libtheora/libtheora-1.1.1.ebuild b/media-libs/libtheora/libtheora-1.1.1.ebuild
new file mode 100644
index 000000000000..c10e27091414
--- /dev/null
+++ b/media-libs/libtheora/libtheora-1.1.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/libtheora-1.1.1.ebuild,v 1.1 2009/10/27 11:16:37 aballier Exp $
+
+EAPI=2
+inherit autotools eutils flag-o-matic
+
+DESCRIPTION="The Theora Video Compression Codec"
+HOMEPAGE="http://www.theora.org"
+SRC_URI="http://downloads.xiph.org/releases/theora/${P/_}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc +encode examples"
+
+RDEPEND="media-libs/libogg
+	encode? ( media-libs/libvorbis )
+	examples? ( media-libs/libpng
+		media-libs/libvorbis
+		>=media-libs/libsdl-0.11.0 )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	dev-util/pkgconfig"
+
+VARTEXFONTS=${T}/fonts
+S=${WORKDIR}/${P/_}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.0_beta2-flags.patch
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	use x86 && filter-flags -fforce-addr -frename-registers #200549
+	use doc || export ac_cv_prog_HAVE_DOXYGEN="false"
+
+	local myconf
+	use examples && myconf="--enable-encode"
+
+	# --disable-spec because LaTeX documentation has been prebuilt
+	econf \
+		--disable-dependency-tracking \
+		--disable-spec \
+		$(use_enable encode) \
+		$(use_enable examples) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} \
+		install || die "emake install failed"
+
+	dodoc AUTHORS CHANGES README
+	prepalldocs
+
+	if use examples; then
+		if use doc; then
+			insinto /usr/share/doc/${PF}/examples
+			doins examples/*.[ch]
+		fi
+
+		dobin examples/.libs/png2theora || die "dobin failed"
+		for bin in dump_{psnr,video} {encoder,player}_example; do
+			newbin examples/.libs/${bin} theora_${bin} || die "newbin failed"
+		done
+	fi
+}