Revision bump: add compatibility with recent yaml-cpp, wrt bug #471366

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

3 files changed, 95 insertions, 2 deletions

diff --git a/media-libs/opencolorio/ChangeLog b/media-libs/opencolorio/ChangeLog
index 07b36cf778ed..58fcdbe3e1d7 100644
--- a/media-libs/opencolorio/ChangeLog
+++ b/media-libs/opencolorio/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/opencolorio
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/opencolorio/ChangeLog,v 1.8 2013/09/24 11:01:49 pinkbyte Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/opencolorio/ChangeLog,v 1.9 2014/04/23 08:42:42 pinkbyte Exp $
+
+*opencolorio-1.0.9-r1 (23 Apr 2014)
+
+  23 Apr 2014; Sergey Popov <pinkbyte@gentoo.org> +opencolorio-1.0.9-r1.ebuild,
+  +files/opencolorio-1.0.9-yaml-0.5-compat.patch.bz2:
+  Revision bump: add compatibility with recent yaml-cpp, wrt bug #471366
 
 *opencolorio-1.0.9 (24 Sep 2013)
 
diff --git a/media-libs/opencolorio/files/opencolorio-1.0.9-yaml-0.5-compat.patch.bz2 b/media-libs/opencolorio/files/opencolorio-1.0.9-yaml-0.5-compat.patch.bz2
new file mode 100644
index 000000000000..b6f62e1e0f0c
--- /dev/null
+++ b/media-libs/opencolorio/files/opencolorio-1.0.9-yaml-0.5-compat.patch.bz2
diff --git a/media-libs/opencolorio/opencolorio-1.0.9-r1.ebuild b/media-libs/opencolorio/opencolorio-1.0.9-r1.ebuild
new file mode 100644
index 000000000000..5dacef03323e
--- /dev/null
+++ b/media-libs/opencolorio/opencolorio-1.0.9-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/opencolorio/opencolorio-1.0.9-r1.ebuild,v 1.1 2014/04/23 08:42:42 pinkbyte Exp $
+
+EAPI=5
+
+# Compatibility with Python 3 is declared by upstream, but it is broken in fact, check on bump
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils python-single-r1 vcs-snapshot
+
+DESCRIPTION="A color management framework for visual effects and animation"
+HOMEPAGE="http://opencolorio.org/"
+SRC_URI="https://github.com/imageworks/OpenColorIO/archive/v${PV}.tar.gz \
+		-> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc opengl pdf python sse2 test"
+
+RDEPEND="opengl? (
+		media-libs/lcms:2
+		>=media-libs/openimageio-1.1.0
+		media-libs/glew
+		media-libs/freeglut
+		virtual/opengl
+		)
+	python? ( ${PYTHON_DEPS} )
+	>=dev-cpp/yaml-cpp-0.5
+	dev-libs/tinyxml
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		pdf? ( dev-python/sphinx[latex,${PYTHON_USEDEP}] )
+		!pdf? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	)
+	"
+
+# Documentation building requires Python bindings building
+REQUIRED_USE="doc? ( python )"
+
+# Restricting tests, bugs #439790 and #447908
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.8-documentation-gen.patch"
+	"${FILESDIR}/${P}-remove-external-doc-utilities.patch"
+	"${FILESDIR}/${P}-yaml-0.5-compat.patch.bz2"
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	use python && python_fix_shebang .
+}
+
+src_configure() {
+	# Missing features:
+	# - Truelight and Nuke are not in portage for now, so their support are disabled
+	# - Java bindings was not tested, so disabled
+	# Notes:
+	# - OpenImageIO is required for building ociodisplay and ocioconvert (USE opengl)
+	# - OpenGL, GLUT and GLEW is required for building ociodisplay (USE opengl)
+	local mycmakeargs=(
+		-DOCIO_BUILD_JNIGLUE=OFF
+		-DOCIO_BUILD_NUKE=OFF
+		-DOCIO_BUILD_SHARED=ON
+		-DOCIO_BUILD_STATIC=OFF
+		-DOCIO_STATIC_JNIGLUE=OFF
+		-DOCIO_BUILD_TRUELIGHT=OFF
+		-DUSE_EXTERNAL_LCMS=ON
+		-DUSE_EXTERNAL_TINYXML=ON
+		-DUSE_EXTERNAL_YAML=ON
+		$(cmake-utils_use doc OCIO_BUILD_DOCS)
+		$(cmake-utils_use opengl OCIO_BUILD_APPS)
+		$(cmake-utils_use pdf OCIO_BUILD_PDF_DOCS)
+		$(cmake-utils_use python OCIO_BUILD_PYGLUE)
+		$(cmake-utils_use sse2 OCIO_USE_SSE)
+		$(cmake-utils_use test OCIO_BUILD_TESTS)
+	)
+	cmake-utils_src_configure
+}