Version bump, use EAPI 1 to provide some decent defaults for IUSE.

(Portage version: 2.1.4_rc14)

3 files changed, 194 insertions, 2 deletions

diff --git a/media-libs/xine-lib/ChangeLog b/media-libs/xine-lib/ChangeLog
index 3636e296b9ec..f48209c1b27c 100644
--- a/media-libs/xine-lib/ChangeLog
+++ b/media-libs/xine-lib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/xine-lib
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.485 2007/12/30 14:04:13 flameeyes Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.486 2008/01/06 20:09:03 flameeyes Exp $
+
+*xine-lib-1.1.9 (06 Jan 2008)
+
+  06 Jan 2008; Diego Pettenò <flameeyes@gentoo.org> +xine-lib-1.1.9.ebuild:
+  Version bump, use EAPI 1 to provide some decent defaults for IUSE.
 
   30 Dec 2007; Diego Pettenò <flameeyes@gentoo.org> metadata.xml:
   Document non-obvious USE flags on metadata.xml.
diff --git a/media-libs/xine-lib/files/digest-xine-lib-1.1.9 b/media-libs/xine-lib/files/digest-xine-lib-1.1.9
new file mode 100644
index 000000000000..51b542a7323c
--- /dev/null
+++ b/media-libs/xine-lib/files/digest-xine-lib-1.1.9
@@ -0,0 +1,3 @@
+MD5 65d18f8c50e4bc86d905097ce234d1ac xine-lib-1.1.9.tar.bz2 7391259
+RMD160 179dc66d13f5f1dcdf134ac82ed71b905c7332e8 xine-lib-1.1.9.tar.bz2 7391259
+SHA256 59194dc75c9da4b186ed53bfd0c39d9070be062034d5b122d578ac00ab236818 xine-lib-1.1.9.tar.bz2 7391259
diff --git a/media-libs/xine-lib/xine-lib-1.1.9.ebuild b/media-libs/xine-lib/xine-lib-1.1.9.ebuild
new file mode 100644
index 000000000000..712d560de408
--- /dev/null
+++ b/media-libs/xine-lib/xine-lib-1.1.9.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/xine-lib-1.1.9.ebuild,v 1.1 2008/01/06 20:09:03 flameeyes Exp $
+
+EAPI=1
+
+inherit eutils flag-o-matic toolchain-funcs libtool
+
+# This should normally be empty string, unless a release has a suffix.
+if [[ "${P/_pre/}" != "${P}" ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else
+	MY_PKG_SUFFIX=""
+	MY_P="${PN}-${PV/_/-}${MY_PKG_SUFFIX}"
+	S="${WORKDIR}/${MY_P}"
+
+	SRC_URI="mirror://sourceforge/xine/${MY_P}.tar.bz2"
+fi
+
+DESCRIPTION="Core libraries for Xine movie player"
+HOMEPAGE="http://xine.sourceforge.net"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="-aalib -libcaca -arts esd win32codecs nls +dvd +X directfb +vorbis +alsa
+gnome sdl speex +theora ipv6 altivec opengl aac -fbcon +xv xvmc
+-samba dxr3 vidix mng -flac -oss +v4l xinerama vcd +a52 +mad -imagemagick +dts
+-debug +modplug -gtk pulseaudio -mmap -truetype wavpack +musepack +xcb -jack
+-real"
+
+RDEPEND="X? ( x11-libs/libXext
+	x11-libs/libX11 )
+	xv? ( x11-libs/libXv )
+	xvmc? ( x11-libs/libXvMC )
+	xinerama? ( x11-libs/libXinerama )
+	win32codecs? ( >=media-libs/win32codecs-0.50 )
+	esd? ( media-sound/esound )
+	dvd? ( >=media-libs/libdvdcss-1.2.7 )
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	aalib? ( media-libs/aalib )
+	directfb? ( >=dev-libs/DirectFB-0.9.9 )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	flac? ( >=media-libs/flac-1.1.2 )
+	sdl? ( >=media-libs/libsdl-1.1.5 )
+	dxr3? ( >=media-libs/libfame-0.9.0 )
+	vorbis? ( media-libs/libogg media-libs/libvorbis )
+	theora? ( media-libs/libogg media-libs/libvorbis >=media-libs/libtheora-1.0_alpha6 )
+	speex? ( media-libs/libogg media-libs/libvorbis media-libs/speex )
+	libcaca? ( >=media-libs/libcaca-0.99_beta1 )
+	samba? ( net-fs/samba )
+	mng? ( media-libs/libmng )
+	vcd? ( media-video/vcdimager )
+	a52? ( >=media-libs/a52dec-0.7.4-r5 )
+	mad? ( media-libs/libmad )
+	imagemagick? ( media-gfx/imagemagick )
+	dts? ( || ( media-libs/libdca media-libs/libdts ) )
+	>=media-video/ffmpeg-0.4.9_p20070129
+	modplug? ( media-libs/libmodplug )
+	nls? ( virtual/libintl )
+	gtk? ( =x11-libs/gtk+-2* )
+	pulseaudio? ( media-sound/pulseaudio )
+	truetype? ( =media-libs/freetype-2* media-libs/fontconfig )
+	virtual/libiconv
+	wavpack? ( >=media-sound/wavpack-4.31 )
+	musepack? ( media-libs/libmpcdec )
+	xcb? ( >=x11-libs/libxcb-1.0 )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
+	real? (
+		x86? ( media-libs/win32codecs )
+		x86-fbsd? ( media-libs/win32codecs )
+		amd64? ( media-libs/amd64codecs ) )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-libs/libXt
+		 x11-proto/xproto
+		 x11-proto/videoproto
+		 x11-proto/xf86vidmodeproto
+		 xinerama? ( x11-proto/xineramaproto ) )
+	v4l? ( virtual/os-headers )
+	dev-util/pkgconfig
+	sys-devel/libtool
+	nls? ( sys-devel/gettext )"
+
+src_compile() {
+	#prevent quicktime crashing
+	append-flags -frename-registers -ffunction-sections
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		filter-flags -fforce-addr
+		filter-flags -momit-leaf-frame-pointer # break on gcc 3.4/4.x
+		filter-flags -fno-omit-frame-pointer #breaks per bug #149704
+		is-flag -O? || append-flags -O2
+	fi
+
+	local myconf
+
+	# enable/disable appropiate optimizations on sparc
+	[[ "${PROFILE_ARCH}" == "sparc64" ]] && myconf="${myconf} --enable-vis"
+	[[ "${PROFILE_ARCH}" == "sparc" ]] && myconf="${myconf} --disable-vis"
+
+	# The default CFLAGS (-O) is the only thing working on hppa.
+	use hppa && unset CFLAGS
+
+	# Too many file names are the same (xine_decoder.c), change the builddir
+	# So that the relative path is used to identify them.
+	mkdir "${WORKDIR}/build"
+
+	elibtoolize
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable gnome gnomevfs) \
+		$(use_enable nls) \
+		$(use_enable ipv6) \
+		$(use_enable samba) \
+		$(use_enable altivec) \
+		$(use_enable v4l) \
+		\
+		$(use_enable mng) \
+		$(use_with imagemagick) \
+		$(use_enable gtk gdkpixbuf) \
+		\
+		$(use_enable aac faad) \
+		$(use_with flac libflac) \
+		$(use_with vorbis) \
+		$(use_with speex) \
+		$(use_with theora) \
+		$(use_with wavpack) \
+		$(use_enable modplug) \
+		$(use_enable a52 a52dec) --with-external-a52dec \
+		$(use_enable mad) --with-external-libmad \
+		$(use_enable dts) --with-external-libdts \
+		$(use_enable musepack) --with-external-libmpcdec \
+		\
+		$(use_with X x) \
+		$(use_enable xinerama) \
+		$(use_enable vidix) \
+		$(use_enable dxr3) \
+		$(use_enable directfb) \
+		$(use_enable fbcon fb) \
+		$(use_enable opengl) \
+		$(use_enable aalib) \
+		$(use_with libcaca caca) \
+		$(use_with sdl) \
+		$(use_enable xvmc) \
+		$(use_with xcb) \
+		\
+		$(use_enable oss) \
+		$(use_with alsa) \
+		$(use_with arts) \
+		$(use_with esd esound) \
+		$(use_with pulseaudio) \
+		$(use_with jack) \
+		\
+		$(use_enable vcd) --without-internal-vcdlibs \
+		\
+		$(use_enable win32codecs w32dll) \
+		$(use_enable real real-codecs) \
+		\
+		$(use_enable mmap) \
+		$(use_with truetype freetype) $(use_with truetype fontconfig) \
+		\
+		$(use_enable debug) \
+		--enable-asf \
+		--with-external-ffmpeg \
+		--disable-optimizations \
+		--disable-syncfb \
+		${myconf} \
+		--with-xv-path=/usr/$(get_libdir) \
+		--with-w32-path=/usr/$(ABI=x86 get_libdir)/win32 \
+		--with-real-codecs-path=/usr/$(get_libdir)/codecs \
+		--enable-fast-install \
+		--disable-dependency-tracking || die "econf failed."
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" \
+		docdir="/usr/share/doc/${PF}" htmldir="/usr/share/doc/${PF}/html" \
+		install || die "emake install failed."
+}