Version bump.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 66 insertions, 1 deletions

diff --git a/media-plugins/gimp-gmic/ChangeLog b/media-plugins/gimp-gmic/ChangeLog
index 7bc72caae40d..4667facc3594 100644
--- a/media-plugins/gimp-gmic/ChangeLog
+++ b/media-plugins/gimp-gmic/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-plugins/gimp-gmic
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/gimp-gmic/ChangeLog,v 1.51 2015/02/04 17:22:19 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/gimp-gmic/ChangeLog,v 1.52 2015/02/07 21:35:43 radhermit Exp $
+
+*gimp-gmic-1.6.0.4 (07 Feb 2015)
+
+  07 Feb 2015; Tim Harder <radhermit@gentoo.org> +gimp-gmic-1.6.0.4.ebuild:
+  Version bump.
 
   04 Feb 2015; Tim Harder <radhermit@gentoo.org> metadata.xml:
   Drop myself from metadata.
diff --git a/media-plugins/gimp-gmic/gimp-gmic-1.6.0.4.ebuild b/media-plugins/gimp-gmic/gimp-gmic-1.6.0.4.ebuild
new file mode 100644
index 000000000000..c13d05e92c54
--- /dev/null
+++ b/media-plugins/gimp-gmic/gimp-gmic-1.6.0.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/gimp-gmic/gimp-gmic-1.6.0.4.ebuild,v 1.1 2015/02/07 21:35:43 radhermit Exp $
+
+EAPI=5
+
+inherit eutils toolchain-funcs flag-o-matic
+
+DESCRIPTION="G'MIC GIMP plugin"
+HOMEPAGE="http://gmic.sourceforge.net/gimp.shtml"
+SRC_URI="mirror://sourceforge/gmic/gmic_${PV}.tar.gz"
+
+LICENSE="CeCILL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="openmp"
+
+RDEPEND="
+	>=media-gfx/gimp-2.4.0
+	media-libs/libpng:0=
+	sci-libs/fftw:3.0[threads]
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/gmic-${PV}/src
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+
+	if ! test-flag-CXX -std=c++11 ; then
+		die "You need at least GCC 4.7.x or Clang >= 3.3 for C++11-specific compiler flags"
+	fi
+}
+
+src_prepare() {
+	cp "${FILESDIR}"/gmic-1.6.0.2-makefile.patch "${WORKDIR}" || die
+	edos2unix "${WORKDIR}"/gmic-1.6.0.2-makefile.patch
+	epatch "${WORKDIR}"/gmic-1.6.0.2-makefile.patch
+
+	if ! use openmp ; then
+		sed -i -r "s/^(OPENMP_(CFLAGS|LIBS) =).*/\1/" Makefile || die
+	fi
+}
+
+src_compile() {
+	emake CC="$(tc-getCXX)" CFLAGS="${CXXFLAGS}" OPT_CFLAGS= DEBUG_CFLAGS= gimp
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-gimp
+	dodoc ../README
+}
+
+pkg_postinst() {
+	elog "The G'MIC plugin is accessible from the menu:"
+	elog "Filters -> G'MIC"
+}