2.2 now in beta and waiting for you to test it out. Fixed AAC dep & USE-flag, thanks to beandog for finding that one. If you want WMA, you can get that and much more through the ffmpeg USE-flag.

(Portage version: 2.2_rc46/cvs/Linux x86_64)

2 files changed, 122 insertions, 1 deletions

diff --git a/media-plugins/audacious-plugins/ChangeLog b/media-plugins/audacious-plugins/ChangeLog
index 4caea3aea4b4..7e1e2017c1cf 100644
--- a/media-plugins/audacious-plugins/ChangeLog
+++ b/media-plugins/audacious-plugins/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/audacious-plugins
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.141 2009/10/15 10:17:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.142 2009/10/20 21:39:46 chainsaw Exp $
+
+*audacious-plugins-2.2_beta1 (20 Oct 2009)
+
+  20 Oct 2009; <chainsaw@gentoo.org> +audacious-plugins-2.2_beta1.ebuild:
+  2.2 now in beta and waiting for you to test it out. Fixed AAC dep &
+  USE-flag, thanks to beandog for finding that one. If you want WMA, you can
+  get that and much more through the ffmpeg USE-flag.
 
   15 Oct 2009; Samuli Suominen <ssuominen@gentoo.org>
   audacious-plugins-1.5.1-r3.ebuild:
diff --git a/media-plugins/audacious-plugins/audacious-plugins-2.2_beta1.ebuild b/media-plugins/audacious-plugins/audacious-plugins-2.2_beta1.ebuild
new file mode 100644
index 000000000000..e7a422b0103b
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-2.2_beta1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.2_beta1.ebuild,v 1.1 2009/10/20 21:39:46 chainsaw Exp $
+
+inherit eutils flag-o-matic
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://distfiles.atheme.org/${MY_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="aac adplug alsa bs2b cdda esd flac ffmpeg gnome icecast ipv6 jack lirc mp3
+mtp nls oss projectm scrobbler sdl sid sndfile sse2 timidity tta vorbis wavpack"
+
+RDEPEND="app-arch/unzip
+	>=dev-libs/dbus-glib-0.60
+	dev-libs/libxml2
+	>=media-sound/audacious-2.2_beta1
+	>=net-misc/neon-0.26.4
+	>=x11-libs/gtk+-2.14
+	aac? ( >=media-libs/faad2-2.7-r1 )
+	adplug? ( >=dev-cpp/libbinio-1.4 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( >=media-libs/libcddb-1.2.1
+		>=dev-libs/libcdio-0.79-r1 )
+	esd? ( >=media-sound/esound-0.2.38-r1 )
+	flac? ( >=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.2.1-r1 )
+	icecast? ( media-libs/libshout )
+	jack? ( >=media-libs/bio2jack-0.4
+		media-sound/jack-audio-connection-kit )
+	lirc? ( app-misc/lirc )
+	mp3? ( media-libs/libmad )
+	mtp? ( media-libs/libmtp )
+	projectm? ( >=media-libs/libprojectm-1.2.0
+		>=media-libs/libsdl-1.2.5 )
+	scrobbler? ( net-misc/curl )
+	sdl? (	>=media-libs/libsdl-1.2.5 )
+	sid? ( >=media-libs/libsidplay-2.1.1-r2 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	timidity? ( media-sound/timidity++ )
+	tta? ( media-libs/libid3tag )
+	vorbis? ( >=media-libs/libvorbis-1.2.0
+		  >=media-libs/libogg-1.1.3 )
+	wavpack? ( >=media-sound/wavpack-4.41.0 )"
+
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	>=dev-util/pkgconfig-0.9.0"
+
+mp3_warning() {
+	if ! useq mp3 ; then
+		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+	fi
+}
+
+src_compile() {
+	mp3_warning
+
+	econf \
+		--enable-chardet \
+		--enable-dbus \
+		--enable-modplug \
+		--enable-neon \
+		--disable-coreaudio \
+		--disable-dockalbumart \
+		--disable-projectm \
+		$(use_enable adplug) \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable alsa bluetooth) \
+		$(use_enable bs2b) \
+		$(use_enable cdda cdaudio) \
+		$(use_enable esd) \
+		$(use_enable ffmpeg ffaudio) \
+		$(use_enable flac flacng) \
+		$(use_enable flac filewriter_flac) \
+		$(use_enable icecast) \
+		$(use_enable ipv6) \
+		$(use_enable jack) \
+		$(use_enable gnome gnomeshortcuts) \
+		$(use_enable lirc) \
+		$(use_enable mp3) \
+		$(use_enable mtp mtp_up) \
+		$(use_enable nls) \
+		$(use_enable oss) \
+		$(use_enable projectm projectm-1.0) \
+		$(use_enable sdl paranormal) \
+		$(use_enable sid) \
+		$(use_enable sndfile) \
+		$(use_enable sse2) \
+		$(use_enable timidity) \
+		$(use_enable tta) \
+		$(use_enable vorbis) \
+		$(use_enable vorbis filewriter_vorbis) \
+		$(use_enable wavpack) \
+		|| die
+
+	emake || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc AUTHORS
+}
+
+pkg_postinst() {
+	mp3_warning
+}