Version bump.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

2 files changed, 69 insertions, 1 deletions

diff --git a/media-sound/mpg123/ChangeLog b/media-sound/mpg123/ChangeLog
index 3b0475411cb1..6d4de51b2247 100644
--- a/media-sound/mpg123/ChangeLog
+++ b/media-sound/mpg123/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.244 2011/07/18 06:53:57 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.245 2011/08/29 10:08:57 radhermit Exp $
+
+*mpg123-1.13.4 (29 Aug 2011)
+
+  29 Aug 2011; Tim Harder <radhermit@gentoo.org> +mpg123-1.13.4.ebuild:
+  Version bump.
 
   18 Jul 2011; Tim Harder <radhermit@gentoo.org> -mpg123-1.12.1.ebuild,
   -mpg123-1.12.3.ebuild, -mpg123-1.12.5.ebuild, -mpg123-1.13.1.ebuild:
diff --git a/media-sound/mpg123/mpg123-1.13.4.ebuild b/media-sound/mpg123/mpg123-1.13.4.ebuild
new file mode 100644
index 000000000000..bf86c165a83a
--- /dev/null
+++ b/media-sound/mpg123/mpg123-1.13.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.13.4.ebuild,v 1.1 2011/08/29 10:08:57 radhermit Exp $
+
+EAPI=4
+inherit toolchain-funcs libtool
+
+DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
+HOMEPAGE="http://www.mpg123.org/"
+SRC_URI="http://www.mpg123.org/download/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="3dnow 3dnowext alsa altivec coreaudio ipv6 jack mmx nas oss portaudio pulseaudio sdl sse"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nas? ( media-libs/nas )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	sys-devel/libtool"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS NEWS.libmpg123 README )
+
+src_prepare() {
+	elibtoolize # for Darwin bundles
+}
+
+src_configure() {
+	local _audio=dummy
+	local _output=dummy
+	local _cpu=generic_fpu
+
+	for flag in nas portaudio sdl oss jack alsa pulseaudio coreaudio; do
+		if use ${flag}; then
+			_audio="${_audio} ${flag/pulseaudio/pulse}"
+			_output=${flag/pulseaudio/pulse}
+		fi
+	done
+
+	use altivec && _cpu=altivec
+
+	if [[ $(tc-arch) == amd64 || ${ARCH} == x64-* ]]; then
+		use sse && _cpu=x86-64
+	else
+		use mmx && _cpu=mmx
+		use 3dnow && _cpu=3dnow
+		use sse && _cpu=x86
+		use 3dnowext && _cpu=x86
+	fi
+
+	econf \
+		--with-optimization=0 \
+		--with-audio="${_audio}" \
+		--with-default-audio=${_output} \
+		--with-cpu=${_cpu} \
+		--enable-network \
+		$(use_enable ipv6)
+}