Add a new qsynth ebuild that allows to specify the pulseaudio output as default, to go with the new fluidsynth.

(Portage version: 2.2_rc30/cvs/Linux x86_64)

2 files changed, 70 insertions, 2 deletions

diff --git a/media-sound/qsynth/ChangeLog b/media-sound/qsynth/ChangeLog
index ae6f2e1e5dd6..a8871d1c0d1e 100644
--- a/media-sound/qsynth/ChangeLog
+++ b/media-sound/qsynth/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/qsynth
-# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.44 2008/10/10 12:29:34 flameeyes Exp $
+# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.45 2009/04/15 20:02:37 flameeyes Exp $
+
+*qsynth-0.3.3-r2 (15 Apr 2009)
+
+  15 Apr 2009; Diego E. Pettenò <flameeyes@gentoo.org>
+  +qsynth-0.3.3-r2.ebuild:
+  Add a new qsynth ebuild that allows to specify the pulseaudio output as
+  default, to go with the new fluidsynth.
 
 *qsynth-0.3.3-r1 (10 Oct 2008)
 
diff --git a/media-sound/qsynth/qsynth-0.3.3-r2.ebuild b/media-sound/qsynth/qsynth-0.3.3-r2.ebuild
new file mode 100644
index 000000000000..6f829df44865
--- /dev/null
+++ b/media-sound/qsynth/qsynth-0.3.3-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.3-r2.ebuild,v 1.1 2009/04/15 20:02:37 flameeyes Exp $
+
+EAPI=2
+
+inherit qt4 eutils flag-o-matic
+
+DESCRIPTION="A Qt application to control FluidSynth"
+HOMEPAGE="http://qsynth.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+IUSE="debug jack alsa pulseaudio"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="
+	|| ( (
+			x11-libs/qt-core:4
+			x11-libs/qt-gui:4
+		) =x11-libs/qt-4.3*:4 )
+	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?,pulseaudio?]
+	!pulseaudio? ( !jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) ) )"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	# Stupidly, qsynth's configure does *not* use pkg-config to
+	# discover the presence of Qt4, but uses fixed paths; as they
+	# don't really work that well for our case, let's just use this
+	# nasty hack and be done with it. *NOTE*: this hinders
+	# cross-compile.
+	append-flags -I/usr/include/qt4
+	append-ldflags -L/usr/$(get_libdir)/qt4
+
+	econf \
+		$(use_enable debug) \
+		|| die "econf failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README TODO
+
+	# The desktop file is invalid, and we also change the command
+	# depending on useflags
+	rm -rf "${D}/usr/share/applications/qsynth.desktop"
+
+	local cmd
+	if use jack; then
+		cmd="qsynth"
+	elif use pulseaudio; then
+		cmd="qsynth -a pulseaudio"
+	elif use alsa; then
+		cmd="qsynth -a alsa"
+	else
+		cmd="qsynth -a oss"
+	fi
+
+	make_desktop_entry "${cmd}" Qsynth qsynth
+}