Version bump.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 4F064CA3)

2 files changed, 88 insertions, 1 deletions

diff --git a/media-sound/moc/ChangeLog b/media-sound/moc/ChangeLog
index 1e3635d0bb88..85687f443586 100644
--- a/media-sound/moc/ChangeLog
+++ b/media-sound/moc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/moc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.115 2014/02/07 03:42:28 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.116 2014/08/31 05:12:40 radhermit Exp $
+
+*moc-2.5.0 (31 Aug 2014)
+
+  31 Aug 2014; Tim Harder <radhermit@gentoo.org> +moc-2.5.0.ebuild:
+  Version bump.
 
 *moc-2.5.0_beta2 (07 Feb 2014)
 
diff --git a/media-sound/moc/moc-2.5.0.ebuild b/media-sound/moc/moc-2.5.0.ebuild
new file mode 100644
index 000000000000..5a1b099816ff
--- /dev/null
+++ b/media-sound/moc/moc-2.5.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/moc-2.5.0.ebuild,v 1.1 2014/08/31 05:12:40 radhermit Exp $
+
+EAPI=5
+
+MY_P=${P/_/-}
+DESCRIPTION="Music On Console - ncurses interface for playing audio files"
+HOMEPAGE="http://moc.daper.net"
+SRC_URI="http://ftp.daper.net/pub/soft/moc/stable/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
+	oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
+
+# libltdl from libtool is used at runtime
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	sys-libs/ncurses[unicode?]
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cache? ( >=sys-libs/db-4 )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
+	magic? ( sys-apps/file )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( media-sound/musepack-tools media-libs/taglib )
+	sid? ( >=media-libs/libsidplay-2 )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex )
+	timidity? ( media-libs/libtimidity media-sound/timidity++ )
+	vorbis? (
+		media-libs/libogg
+		tremor? ( media-libs/tremor )
+		!tremor? ( media-libs/libvorbis )
+	)
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local myconf=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug)
+		$(use_enable cache)
+		$(use_with oss)
+		$(use_with alsa)
+		$(use_with jack)
+		$(use_with magic)
+		$(use_with unicode ncursesw)
+		$(use_with libsamplerate samplerate)
+		$(use_with aac)
+		$(use_with ffmpeg)
+		$(use_with flac)
+		$(use_with modplug)
+		$(use_with mad mp3)
+		--without-rcc
+		$(use_with musepack)
+		$(use_with sid sidplay2)
+		$(use_with sndfile)
+		$(use_with speex)
+		$(use_with timidity)
+		$(use_with vorbis vorbis $(usex tremor tremor ""))
+		$(use_with wavpack)
+		$(use_with curl)
+		)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}