version bump

(Portage version: 2.2_rc12/cvs/Linux 2.6.27.3 x86_64)

1 files changed, 65 insertions, 0 deletions

diff --git a/media-video/mkvtoolnix/mkvtoolnix-2.4.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-2.4.0.ebuild
new file mode 100644
index 000000000000..6b2750bf5be5
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-2.4.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-2.4.0.ebuild,v 1.1 2008/10/25 15:49:38 aballier Exp $
+
+EAPI="1"
+inherit eutils wxwidgets flag-o-matic qt4 autotools
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="wxwindows flac bzip2 lzo qt4 debug"
+
+DEPEND=">=dev-libs/libebml-0.7.7
+	>=media-libs/libmatroska-0.8.1
+	media-libs/libogg
+	media-libs/libvorbis
+	dev-libs/expat
+	sys-libs/zlib
+	dev-libs/boost
+	wxwindows? ( =x11-libs/wxGTK-2.8* )
+	flac? ( media-libs/flac )
+	bzip2? ( app-arch/bzip2 )
+	lzo? ( dev-libs/lzo )
+	qt4? ( || ( x11-libs/qt-gui:4 =x11-libs/qt-4.3* ) )"
+
+pkg_setup() {
+	WX_GTK_VER="2.8"
+	if use wxwindows; then
+		need-wxwidgets unicode
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	eautoreconf
+}
+
+src_compile() {
+	use wxwindows && myconf="--with-wx-config=${WX_CONFIG}"
+	econf \
+		$(use_enable lzo) \
+		$(use_enable bzip2 bz2) \
+		$(use_enable wxwindows wxwidgets) \
+		$(use_enable debug) \
+		$(use_with flac) \
+		$(use_enable qt4 qt) \
+		${myconf} \
+		|| die "./configure died"
+
+	# Don't run strip while installing stuff, leave to portage the job.
+	emake STRIP="true" || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" STRIP="true" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README TODO
+	dohtml doc/mkvmerge-gui.html doc/images/*
+	docinto examples
+	dodoc examples/*
+}