Version bump

(Portage version: 2.1.10.45/cvs/Linux x86_64)

2 files changed, 80 insertions, 2 deletions

diff --git a/media-video/bombono-dvd/ChangeLog b/media-video/bombono-dvd/ChangeLog
index 8bcb87c7023d..003af7e01efb 100644
--- a/media-video/bombono-dvd/ChangeLog
+++ b/media-video/bombono-dvd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/bombono-dvd
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/bombono-dvd/ChangeLog,v 1.21 2011/12/06 22:34:58 dilfridge Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/bombono-dvd/ChangeLog,v 1.22 2012/02/12 16:48:11 dilfridge Exp $
+
+*bombono-dvd-1.2.1 (12 Feb 2012)
+
+  12 Feb 2012; Andreas K. Huettel <dilfridge@gentoo.org>
+  +bombono-dvd-1.2.1.ebuild:
+  Version bump
 
 *bombono-dvd-1.2.0-r2 (06 Dec 2011)
 
diff --git a/media-video/bombono-dvd/bombono-dvd-1.2.1.ebuild b/media-video/bombono-dvd/bombono-dvd-1.2.1.ebuild
new file mode 100644
index 000000000000..630143a37759
--- /dev/null
+++ b/media-video/bombono-dvd/bombono-dvd-1.2.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/bombono-dvd/bombono-dvd-1.2.1.ebuild,v 1.1 2012/02/12 16:48:11 dilfridge Exp $
+
+EAPI=4
+SCONS_MIN_VERSION="0.96.1"
+
+inherit base scons-utils toolchain-funcs flag-o-matic virtualx
+
+DESCRIPTION="GUI DVD authoring program"
+HOMEPAGE="http://www.bombono.org/"
+SRC_URI="mirror://sourceforge/bombono/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+
+IUSE="gnome"
+
+COMMONDEPEND="
+	app-i18n/enca
+	app-cdr/dvd+rw-tools
+	dev-cpp/gtkmm:2.4
+	dev-cpp/libxmlpp:2.6
+	>=dev-libs/boost-1.47
+	media-libs/libdvdread
+	media-sound/twolame
+	media-video/dvdauthor
+	virtual/cdrtools
+	virtual/ffmpeg
+	>=media-video/mjpegtools-1.8.0
+	x11-libs/gtk+:2
+"
+RDEPEND="${COMMONDEPEND}
+	gnome?	( gnome-base/gvfs )
+"
+DEPEND="${COMMONDEPEND}
+	dev-util/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.1-cflags.patch"
+	"${FILESDIR}/${PN}-1.2.0-cdrtools.patch"
+)
+
+src_configure() {
+	append-flags -DBOOST_SYSTEM_NO_DEPRECATED -DBOOST_FILESYSTEM_VERSION=2
+	myesconsargs=(
+		CC="$(tc-getCC)"
+		CXX="$(tc-getCXX)"
+		CFLAGS="${CFLAGS}"
+		CXXFLAGS="${CXXFLAGS}"
+		DESTDIR="${D}"
+		LDFLAGS="${LDFLAGS}"
+		USE_EXT_BOOST=1
+		PREFIX="${EPREFIX}/usr"
+	)
+}
+
+src_compile() {
+	nonfatal escons \
+		|| die 'Please add "${S}/config.opts" when filing bugs reports!'
+}
+
+src_test() {
+	VIRTUALX_COMMAND="escons TEST=1" virtualmake
+}
+
+src_install() {
+	nonfatal escons install || die 'Please add "${S}/config.opts" when filing bugs reports!'
+}